OBJECT SET TITLE
OBJECT SET TITLE ( * ; object : Text ; title : Text )
OBJECT SET TITLE ( object : Variable, Field ; title : Text )
| Parameter | Type | Description | |
|---|---|---|---|
| * | Operator | → | If specified, object is an Object Name (String) If omitted, object is a Variable |
| object | any | → | Object Name (if * is specified), or Variable (if * is omitted) |
| title | Text | → | New title for the object |
History
| Release | Changes |
|---|---|
| <6 | Created |
| 6 | Modified |
| 12 | Renamed |
Description
The OBJECT SET TITLE command changes the title of the object(s) specified by object to the value you pass in title.
If you specify the optional * parameter, you indicate an object name (a string) in object. If you omit the optional * parameter, you indicate a field or a variable in object. In this case, you specify a field or variable reference (field or variable objects only) instead of a string. For more information about object names, see the section Object Properties.
OBJECT SET TITLE can be applied to any simple objects that display a title:
- buttons and 3D buttons,
- check boxes and 3D check boxes,
- radio buttons and 3D radio buttons,
- list box headers,
- static text areas,
- group boxes.
Usually, you will apply this command to one object at a time. The object title area must be big enough to hold the text; otherwise, the text is truncated.
Do not use carriage returns in title.
If you want to set a title on more than one line, use the "\" character ("\\" in the code editor) as a line return. This is permitted for 3D buttons, 3D check boxes, 3D radio buttons and list box headers.
Note: Pass "\\\" when you want to use the "\" character in the title.
Example 1
The following example is the object method of a search button located in the footer area of an output form displayed using MODIFY SELECTION. The method searches a table; depending on the search results, it enables or disables a button labeled bDelete and changes its title:
QUERY([People];[People]Name=vName)
Case of
:(Records in selection([People])=0) // No people found
OBJECT SET TITLE(bDelete;" Delete")
OBJECT SET ENABLED(bDelete;False)
:(Records in selection([People])=1) // One person found
OBJECT SET TITLE(bDelete;"Delete Person")
OBJECT SET ENABLED(bDelete;True)
:(Records in selection([People])>1) // Many people found
OBJECT SET TITLE(bDelete;"Delete People")
OBJECT SET ENABLED(bDelete;True)
End case
Example 2
You want to insert titles on two lines:
OBJECT SET TITLE(*;"header1";"Ascending sort \\\ \\Descending sort")
OBJECT SET TITLE(*;"button1";"Click here \\to print")
See also
Properties
| Command number | 194 |
| Thread safe | no |