Clases

Generalidades

El lenguaje 4D soporta el concepto de clases. En un lenguaje de programación, el uso de una clase permite definir el comportamiento de un objeto con propiedades y funciones asociadas.

Cada objeto es una instancia de su clase. Una vez definida una clase usuario, puede instanciar los objetos de esta clase en cualquier parte de su código. Una clase puede extenderse a otra clase con la palabra clave extender y entonces hereda sus funciones y sus propiedades (declarada y calculada).

El modelo de clases en 4D es similar al de las clases en JavaScript, y se basa en una cadena de prototipos.

Por ejemplo, puede crear una clase Person con la siguiente definición:

//Class: Person.4dm
Class constructor($firstname : Text; $lastname : Text)
 This.firstName:=$firstname
 This.lastName:=$lastname

Function get fullName() -> $fullName : text
 $fullName:=This.firstName+" "+This.lastName

Function sayHello()->$welcome : Text
 $welcome:="Hello "+This.fullName

En un método, creando una "Persona":

var $person : cs.Person //object of Person class  
var $hello : Text
$person:=cs.Person.new("John";"Doe")
// $person:{firstName: "John"; lastName: "Doe"; fullName: "John Doe"}
$hello:=$person.sayHello() //"Hello John Doe"

Gestión de clases

Definición de una clase

Una clase usuario en 4D está definida por un archivo método específico (.4dm), almacenado en la carpeta /Project/Sources/Classes/. El nombre del archivo es el nombre de la clase.

Al nombrar las clases, debe tener en cuenta las siguientes reglas:

• Un nombre de clase debe cumplir con reglas de denominación de las propiedades.
• .
• No se recomienda dar el mismo nombre a una clase y a una tabla de la base, para evitar conflictos.

Por ejemplo, si quiere definir una clase llamada "Polygon", tiene que crear el siguiente archivo:

Project folder Project Sources Classes Polygon.4dm

Borrar una clase

Para eliminar una clase existente, puede:

• en su disco, elimine el archivo de clase .4dm de la carpeta "Classes",
• en el Explorador 4D, seleccionar la clase y hacer clic en o elegir Mover a la papelera en el menú contextual.

Utilizar la interfaz 4D

Los archivos de clase se almacenan automáticamente en la ubicación adecuada cuando se crean a través de la interfaz de 4D, ya sea a través del menú Archivo o del Explorador.

Menú Archivo y barra de herramientas

Puede crear un nuevo archivo de clase para el proyecto seleccionando Nueva > Clase... en el menú Archivo de 4D Developer o en la barra de herramientas.

También puede utilizar el atajo Ctrl+Mayús+Alt+k.

Explorador

En la página Métodos del Explorador, las clases se agrupan en la categoría Clases.

Para crear una nueva clase, puede:

• seleccione la categoría Clases y haga clic en el botón .
• seleccione Nueva clase... en el menú de acciones de la parte inferior de la ventana del Explorador, o en el menú contextual del grupo Clases.
• seleccione Nueva > Clase... en el menú contextual de la página de inicio del Explorador.

Soporte del código de clase

En las diferentes ventanas 4D (editor de código, compilador, depurador, explorador de ejecución), el código de la clase se maneja básicamente como un método proyecto con algunas especificidades:

• En el editor de código:
  • una clase no puede ser ejecutada
  • una función de clase es un bloque de código
  • Ir a la definición en un objeto miembro busca las declaraciones de función de clase; por ejemplo, "$o.f()" encontrará "Function f".
  • Buscar referencias en la declaración de función de clase busca la función utilizada como miembro de objeto; por ejemplo, "Function f" encontrará "$o.f()".
• En el explorador de ejecución y en el depurador, las funciones clase se muestran con el constructor \<ClassName> o formato \<ClassName>.\<FunctionName>.

Class stores

Las clases disponibles son accesibles desde sus class stores. Hay dos class stores disponibles:

• cs para el class store usuario
• 4D para el class store integrado

cs

cs : Object

Parámetros	Tipo		Descripción
classStore	Object	<-	Class store usuario para el proyecto o componente

|

El comando cs devuelve el almacén de clases de usuario del proyecto o componente actual. Devuelve todas las clases de usuario definidas en el proyecto o componente abierto. Por defecto, sólo las clases ORDA están disponibles.

Ejemplo

Quiere crear una nueva instancia de un objeto de myClass:

$instance:=cs.myClass.new()

4D

4D : Object

Parámetros	Tipo		Descripción
classStore	Object	<-	Class store 4D

|

El comando 4D devuelve el almacén de clases para las clases integradas disponibles en 4D. Ofrece acceso a las APIs específicas como CryptoKey.

Ejemplo

Quiere crear una nueva llave en la clase CryptoKey:

$key:=4D.CryptoKey.new(New object("type";"ECDSA";"curve";"prime256v1"))

El objeto clase

Cuando una clase es definida en el proyecto, se carga en el entorno del lenguaje 4D. Una clase es un objeto de la clase "Class". Un objeto clase tiene las siguientes propiedades y funciones:

• cadena name
• objeto superclass (null si ninguno)
• función new(), que permite instanciar objetos de clase.

Además, un objeto clase puede hacer referencia a un objeto constructor (opcional).

Un objeto de clase es un objeto compartido y, por tanto, se puede acceder a él desde diferentes procesos de 4D simultáneamente.

Herencia

Si una clase hereda de otra clase (es decir, se utiliza la palabra clave Class extends en su definición), la clase padre es su superclass.

Cuando 4D no encuentra una función o una propiedad en una clase, la busca en su superclass; si no la encuentra, 4D sigue buscando en la superclase de la superclase, y así sucesivamente hasta que no haya más superclase (todos los objetos heredan de la superclase "Object").

Palabras clave de clase

En las definiciones de clase se pueden utilizar palabras claves específicas de 4D:

• Function <Name> para definir las funciones de clase de los objetos.
• Class constructor para inicializar nuevos objetos de la clase.
• property para definir propiedades estáticas de los objetos con un tipo.
• Function get <Name> y Function set <Name> para definir las propiedades calculadas de los objetos.
• Class extends <ClassName> para definir la herencia.

Function

Sintaxis

Function <name>({$parameterName : type; ...}){->$parameterName : type}
// code

Las funciones de clase son propiedades específicas de la clase. Son objetos de la clase 4D.Function.

En el archivo de definición de clase, las declaraciones de función utilizan la palabra clave Function, y el nombre de la función. El nombre de la función debe cumplir con las reglas de nomenclatura de las propiedades.

tip

Comenzar el nombre de la función con un caracter guión bajo ("_") excluirá la función de las funcionalidades de autocompletado en el editor de código 4D. Por ejemplo, si declara Function _myPrivateFunction en MyClass, no se propondrá en el editor de código cuando digite en "cs.MyClass. ".

Inmediatamente después del nombre de la función, los parámetros de la función se pueden declarar con un nombre y un tipo de datos asignados, incluido el parámetro de retorno (opcional). Por ejemplo:

Function computeArea($width : Integer; $height : Integer)->$area : Integer

En una función de clase, el comando This se utiliza como instancia del objeto. Por ejemplo:

Function setFullname($firstname : Text; $lastname : Text)
 This.firstName:=$firstname
 This.lastName:=$lastname

Function getFullname()->$fullname : Text
 $fullname:=This.firstName+" "+Uppercase(This.lastName)

Para una función clase, el comando Current method name devuelve: <ClassName>.<FunctionName>, por ejemplo "MyClass.myFunction".

En el código de la aplicación, las funciones de clases se llaman como los métodos miembros de las instancias de objetos y pueden recibir parámetros si los hay. Se soportan las siguientes sintaxis:

• utilización del operador (). Por ejemplo, myObject.methodName("hello")
• utilización de un método miembro de la clase "4D.Function":
  • apply()
  • call()

Advertencia hilo seguro: si una función clase no es hilo seguro y es llamada por un método con el atributo "Puede ser ejecutado en proceso apropiativo":

• el compilador no genera ningún error (lo que es diferente en comparación con los métodos regulares),
• un error es lanzado por 4D sólo en tiempo de ejecución.

Parámetros

Los parámetros de las funciones se declaran utilizando el nombre del parámetro y su tipo, separados por dos puntos. El nombre del parámetro debe cumplir con las reglas de nomenclatura de las propiedades. Múltiples parámetros (y tipos) están separados por punto y coma (;).

Function add($x; $y : Variant; $z : Integer; $xy : Object)

Si no se declaró el tipo, el parámetro se definirá como Variant.

Valor devuelto

Se declara el parámetro de retorno (opcional) añadiendo una flecha (->) y la definición del parámetro de retorno después de la lista de parámetros de entrada, o dos puntos (:) y el tipo de parámetro de retorno únicamente. Por ejemplo:

Function add($x : Variant; $y : Integer)->$result : Integer
 $result:=$x+$y

También puede declarar el parámetro de retorno añadiendo sólo: type y utilizar la expresión retorno (también terminará la ejecución de la función). Por ejemplo:

Function add($x : Variant; $y : Integer): Integer
 // algo de código
 return $x+$y

Ejemplo 1

// Clase: Rectangle
property name : Text
property height; width : Integer

Class constructor($width : Integer; $height : Integer)
 This.name:="Rectangle"
 This.height:=$height
 This.width:=$width

// Definición de función
Function getArea()->$result : Integer
 $result:=(This.height)*(This.width)

// En un método proyecto

var $rect : cs.Rectangle
var $area : Real

$rect:=cs.Rectangle.new(50;100)  
$area:=$rect.getArea() //5000

Ejemplo 2

Este ejemplo utiliza la expresión retorno:

Function getRectArea($width : Integer; $height : Integer) : Integer
 If ($width > 0 && $height > 0)
  return $width * $height
 Else
  return 0
 End if

Class Constructor

Sintaxis

// Class: MyClass
Class Constructor({$parameterName : type; ...})
// code
// code

Una función constructora de clase acepta parámetros opcionales y puede ser utilizada para crear e inicializar objetos de la clase del usuario.

Cuando se llama a la función new(), el constructor de clase es llamado con los parámetros opcionalmente pasados a la función new().

Sólo puede haber una función constructora en una clase (de lo contrario se devuelve un error). Un constructor puede utilizar la palabra clave Super para llamar al constructor de la superclase.

Puede crear y escribir propiedades de instancia dentro del constructor (ver ejemplo). Alternativamente, si los valores de sus propiedades de instancia no dependen de parámetros pasados al constructor, puede definirlos utilizando la palabra clave property.

Ejemplo

// Class: MyClass
// Class constructor of MyClass
Class Constructor ($name : Text ; $age : Integer)
 This.name:=$name
 This.age:=$age

// En un método proyecto
// Se puede instanciar un objeto
var $o : cs.MyClass
$o:=cs.MyClass.new("John";42)  
// $o = {"name":"HelloWorld";"age":42}

property

Sintaxis

property <propertyName>{; <propertyName2>;...}{ : <propertyType>}

La palabra claveproperty se puede utilizar para declarar una propiedad dentro de una clase usuario. Una propiedad de clase tiene un nombre y un tipo.

La declaración de propiedades de clase mejora las sugerencias del editor de código, las funciones de tecleo predictivo y la detección de errores.

Las propiedades se declaran para los objetos nuevos cuando se llama a la función new(), sin embargo no se añaden automáticamente a los objetos (sólo se añaden cuando se les asigna un valor).

Los nombres de las propiedades deben cumplir las normas de denominación de propiedades.

El tipo de propiedad puede ser uno de los siguientes tipos soportados:

propertyType	Contenido
Text	Valor texto
Fecha	Valor fecha
Hora	Valor Hora
Boolean	Valor booleano
Integer	Valor entero largo
Real	Valor real
Puntero	Valor puntero
Picture	Valor imagen
Blob	Valeor Blob escalar
Collection	Valor colección
Variant	Valor variant
Object	Objeto con clase por defecto (4D.object)
4D.<className>	Objeto del nombre de la clase 4D
cs.<className>	Objeto del nombre de la clase usuario
cs.<namespace>.<className>	Objeto del nombre de la clase del componente <namespace>

info

La palabra clave property sólo puede utilizarse en métodos clase y fuera de cualquier bloque Function o Class Constructor.

Ejemplo

// Clase: MyClass

property name : Text
property age : Integer

En un método:

var $o : cs.MyClass
$o:=cs.MyClass.new() //$o:{}
$o.name:="John" //$o:{"name" : "John"}
$o.age:="Smith" //error con sintaxis de verificación

Function get y Function set

Sintaxis

Function get <name>()->$result : type
// código

Function set <name>($parameterName : type)
// código

Function get y Function set son accesos que definen las propiedades calculadas en la clase. Una propiedad calculada es una propiedad nombradas con un tipo de datos que enmascara un cálculo. Cuando se accede a un valor de propiedad calculado, 4D sustituye el código del accesor correspondiente:

• cuando se lee la propiedad, Function get se ejecuta,
• cuando se escribe la propiedad, Function get se ejecuta.

Si no se accede a la propiedad, el código nunca se ejecuta.

Las propiedades calculadas están diseñadas para manejar datos que no necesitan ser guardados en memoria. Generalmente se basan en propiedades persistentes. For example, if a class object contains as persistent property the gross price and the VAT rate, the net price could be handled by a computed property.

In the class definition file, computed property declarations use the Function get (the getter) and Function set (the setter) keywords, followed by the name of the property.

In the class definition file, computed property declarations use the Function get (the getter) and Function set (the setter) keywords, followed by the name of the property.

En el archivo de definición de la clase, las declaraciones de propiedades calculadas utilizan las palabras claves Function get (getter) y Function set (setter) seguido por el nombre de la propiedad. El nombre debe cumplir con las reglas de nomenclatura de las propiedades.

Función get devuelve un valor del tipo de la propiedad y Function set toma un parámetro del tipo de la propiedad. Ambos argumentos deben cumplir con los parámetros de función estándar.

Cuando ambas funciones están definidas, la propiedad calculada es read-write. Si solo se define una Function get, la propiedad calculada es de solo lectura. En este caso, se devuelve un error si el código intenta modificar la propiedad. If only a Function set is defined, 4D returns undefined when the property is read.

The type of the computed property is defined by the $return type declaration of the getter.

The type of the computed property is defined by the $return type declaration of the getter.

El tipo de la propiedad calculada es definido por la declaración de tipo $return del *getter *. Puede ser de cualquier tipo de propiedad válido.

Asignar undefined a una propiedad de objeto limpia su valor mientras se preserva su tipo. Para ello, la Function get es llamada primero para recuperar el tipo de valor, luego Function set es llamado con un valor vacío de ese tipo.

Ejemplo 1

//Class: Person.4dm
property firstName; lastName : Text

Class constructor($firstname : Text; $lastname : Text)
 This.firstName:=$firstname
 This.lastName:=$lastname

Function get fullName() -> $fullName : Text
 $fullName:=This.firstName+" "+This.lastName

Function set fullName( $fullName : Text )
 $p:=Position(" "; $fullName)
 This.firstName:=Substring($fullName; 1; $p-1)
 This.lastName:=Substring($fullName; $p+1)

//en un método proyecto
$fullName:=$person.fullName // Function get fullName() is called
$person.fullName:="John Smith" // Function set fullName() is called

Ejemplo 2

Function get fullAddress()->$result : Object

 $result:=New object

 $result.fullName:=This.fullName
 $result.address:=This.address
 $result.zipCode:=This.zipCode
 $result.city:=This.city
 $result.state:=This.state
 $result.country:=This.country

Class extends <ClassName>

Sintaxis

// Class hijo
Class extends <ParentClass>

La palabra clave Class extends se utiliza en la declaración de clase para crear una clase usuario que es hijo de otra clase usuario. La clase hijo hereda todas las funciones de la clase padre.

La extensión de clase debe respetar las siguientes reglas:

• Una clase de usuario no puede extender una clase integrada (excepto las 4D.Object y clases ORDA que se extienden por defecto para las clases de usuario).
• Una clase usuario no puede extender una clase usuario de otro proyecto o componente.
• Una clase usuario no puede extenderse a sí misma.
• No es posible extender las clases de una manera circular (es decir, "a" extiende "b" que extiende "a").

La ruptura de tal regla no es detectada por el editor de código o el intérprete, solo el compilador y comprobar sintaxis arrojará un error en este caso.

Una clase extendida puede llamar al constructor de su clase padre utilizando el comando Super.

Ejemplo

Este ejemplo crea una clase llamada Square de una clase llamada Polygon.

//Class: Square

//path: Classes/Square. dm 

Class extends Polygon

Class constructor ($side : Integer)

 // Llama al constructor de la clase padre con las longitudes
 // proporcionadas para el ancho y alto del polígono
 Super($side;$side)
 // En las clases derivadas, Super debe ser llamado antes de 
 // utilizar 'This'
 This.name:="Square"

 Function getArea()
  C_LONGINT($0)
  $0:=This.height*This.width

Super

Super( ...param : any )
Super : Object

Parámetros	Tipo		Descripción
param	any	->	Parámetro(s) a pasar al constructor de la clase padre
Result	Object	<-	Padre del objeto

|

La palabra clave Super permite realizar llamadas a la superclase, es decir, a la clase padre.

Super tiene dos propósitos diferentes:

1. Dentro de un código constructor, Super es un comando que permite llamar al constructor de la superclase. Cuando se utiliza en un constructor, el comando Super aparece solo y debe ser usado antes de usar la palabra clave This.

• Si todos los class constructors en el árbol de herencia no son llamados correctamente, se genera el error -10748. Es responsabilidad del desarrollador 4D asegurarse de que las llamadas sean válidas.
• Si el comando This es llamado en un objeto cuyas superclases no han sido construidas, se genera el error -10743.
• Si se llama a Super fuera de un contexto de objeto, o en un objeto cuyo constructor de superclase ya ha sido llamado, se genera el error -10746.

// dentro del constructor myClass
var $text1; $text2 : Texto
Super($text1) //llamada del constructor de la superclase con un parámetro texto
Este. aram:=$text2 // usar un segundo parámetro

2. Dentro de una función de clase, Super designa el prototipo de la superclase y permite llamar a una función de la jerarquía de superclases.

Super.doSomething(42) //llama a la función "doSomething"  
//declarada en superclases

Ejemplo 1

Este ejemplo ilustra el uso de Super en un class constructor. El comando es llamado para evitar duplicar las partes del constructor que son comunes entre las clases Rectangle y Square.

// Class: Rectangle
Class constructor($width : Integer; $height : Integer)
 This.name:="Rectangle"
 This.height:=$height
 This.width:=$width


Function sayName()
 ALERT("Hi, I am a "+This.name+".")

// Function definition
Function getArea()
 var $0 : Integer

 $0:=(This.height)*(This.width)

// Function definition
Function getArea()
 var $0 : Integer

 $0:=(This.height)*(This.width)

//Class: Square

Class extends Rectangle

Class constructor ($side : Integer)

 // Llama al class constructor de la clase padre con longitudes
 // proporcionadas para el ancho y alto del rectángulo
 Super($side;$side)
 // En las clases derivadas, Super debe ser llamado antes de que 
 // pueda utilizar 'This'
 This. ame:="Square"

Function getArea()
 C_LONGINT($0)
 $0:=This.height*This.width

Ejemplo 2

Este ejemplo ilustra el uso de Super en un método miembro clase. Ha creado la clase Rectangle con una función:

//Class: Rectangle

Function nbSides()
 var $0 : Text
 $0:="I have 4 sides"

También creó la clase Square con una función que llama a la función superclase:

//Class: Square

Class extends Rectangle

Function description()
 var $0 : Text
 $0:=Super.nbSides()+" which are all equal"

Entonces puede escribir en un método proyecto:

var $square : Objeto
var $message : Texto
$square:=cs.Square.new()
$message:=$square.description() //tengo 4 lados iguales

This

This : Object

Parámetros	Tipo		Descripción
Result	Object	<-	Objeto actual

|

La palabra clave This devuelve una referencia al objeto procesado actualmente.

En la mayoría de los casos, el valor de This está determinado por cómo se llama una función. No se puede definir por asignación durante la ejecución, y puede ser diferente cada vez que se llame a la función.

Cuando una fórmula es llamada como un método miembro de un objeto, su This está definido en el objeto en el que se llama el método. Por ejemplo:

$o:=New object("prop";42;"f";Formula(This.prop))
$val:=$o.f() //42

Cuando se utiliza una función class constructor (con la función new()), su This está vinculado al nuevo objeto que se está construyendo.

//Class: ob

Class Constructor  

    // Crear las propiedades en This 
    // asignándolas
    This.a:=42

// en un método 4D  
$o:=cs.ob.new()
$val:=$o.a //42

Al llamar a la superclase del constructor en un constructor utilizando la palabra clave Super, tenga en cuenta que This no debe ser llamado antes del constructor de la superclase, de lo contrario se genera un error. Ver este ejemplo.

En todos los casos, This se refiere al objeto sobre el que se ha llamado el método, como si el método fuera una función del objeto.

//Class: ob

Function f()
 $0:=This.a+This.b

Entonces puede escribir en un método proyecto:

$o:=cs.ob.new()
$o.a:=5
$o.b:=3
$val:=$o.f() //8

En este ejemplo, el objeto asignado a la variable $o no tiene su propia propiedad f, la hereda de su clase. Como f es llamado como un método de $o, su This se refiere a $o.

Comandos de clases

Varios comandos del lenguaje 4D permiten manejar las funcionalidades de las clases.

OB Class

OB Class ( object ) -> Object | Null

OB Class devuelve la clase del objeto pasado como parámetro.

OB Instance of

OB Instance of ( object ; class ) -> Boolean

OB Instance of devuelve true si object pertenece a la class o a una de las clases heredadas y false de lo contrario.