Especifica lo que se pega. Especifica lo que se pega.Valores posibles: Valores posibles: | Valor | Descripción |
|---|
vk clipboard options all (por defecto) | Pega todos los objetos de datos, incluyendo los valores, formato y fórmulas. |
| Valor | Descripción |
|---|
vk clipboard options all (por defecto) | Pega todos los objetos de datos, incluyendo los valores, formato y fórmulas. | vk clipboard options formatting | Pega solo el formato. | vk clipboard options formulas | Pega sólo las fórmulas. | vk clipboard options formulas and formatting | Pega las fórmulas y el formato. | vk clipboard options values | Pega solo los valores. | vk clipboard options value and formatting | Copia los valores y el formato. |
Se tienen en cuenta las opciones de pegado definidas en las opciones del libro de trabajo.
Para copiar el contenido, los valores, el formato y las fórmulas de un rango origen:
var $originRange; $targetRange; $options : Object
$originRange:=VP Cells("ViewProArea"; 0; 0; 2; 5)
$targetRange:=VP Cells("ViewProArea"; 4; 0; 2; 5)
$options:=New object
$options.copy:=True
$options.pasteOptions:=vk clipboard options all
VP MOVE CELLS($originRange; $targetRange; $options)
VP Copy to object
VP PASTE FROM OBJECT
VP SET WORKBOOK OPTIONS
VP Name ( vpAreaName : Text ; rangeName : Text { ; sheet : Integer } ) : Object
| Parámetros | Tipo | | Descripción |
|---|
| vpAreaName | Text | -> | Nombre de objeto formulario área 4D View Pro | | rangeName | Text | -> | Nombre del rango existente | | sheet | Integer | -> | Ubicación del rango (hoja actual si se omite) | | Resultado | Object | <- | Rango de nombre |
El comando VP Name devuelve un nuevo objeto de rango que hace referencia a un rango con nombre.
En vpAreaName, pase el nombre del área 4D View Pro. Si pasa un nombre que no existe, se devuelve un error.
El parámetro rangeName indica un rango de celdas con nombre existente.
En el parámetro opcional sheet, puede designar una hoja específica donde se definirá el rango rangeName. Si se omite, se utiliza por defecto la hoja de cálculo actual. Puede seleccionar explícitamente la hoja de cálculo actual o todo el libro de trabajo con las siguientes constantes:
vk current sheetvk workbook
Quiere asignar un valor al rango llamado "Total".
// llama la celda B5 Total
VP ADD RANGE NAME(VP Cell("ViewProArea";1;4);"Total")
$name:=VP Name("ViewProArea";"Total")
VP SET NUM VALUE($name;285;"$#,###.00")
VP ADD RANGE NAME
VP ALL
VP Cell
VP Cells
VP Column
VP Combine ranges
VP Get names
VP REMOVE NAME
VP Row
VP NEW DOCUMENT ( vpAreaName : Text )
| Parámetros | Tipo | | Descripción |
|---|
| vpAreaName | Text | -> | Nombre de objeto formulario área 4D View Pro |
El comando VP NEW DOCUMENT carga y muestra un documento nuevo y predeterminado en el objeto área de formulario de 4D View Pro vpAreaName. El nuevo documento vacío sustituye a los datos ya insertados en el área.
En vpAreaName, pase el nombre del área 4D View Pro. Si pasa un nombre que no existe, se devuelve un error.
Quiere mostrar un documento vacío en el objeto formulario "myVPArea":
VP NEW DOCUMENT("myVPArea")
VP IMPORT DOCUMENT
VP Object to font ( fontObj : Object ) : Text
| Parámetros | Tipo | | Descripción |
|---|
| font object | Object | -> | Objeto fuente | | Resultado | Text | <- | Fuente abreviada |
El comando VP Object to font devuelve una cadena abreviada de fuente a partir de fontObj.
En fontObj, pase un objeto que contenga las propiedades de la fuente. Se soportan las siguientes propiedades:
| Propiedad | Tipo | Descripción | Valores posibles | Obligatorio |
|---|
| family | text | Define la fuente. | todo tipo de familia de fuentes estándar o genérica. Ej. "Arial", "Helvetica", "serif", "arial,sans-serif" | Sí | | size | text | Defines the size of the font. The line-height can be added to the font-size: font-size/line-height: Ex: "15pt/20pt" | un número con una de las siguientes unidades: "em", "ex", "%", "px", "cm", "mm", "in", "pt", "pc", "ch", "rem", "vh", "vw", "vmin", "vmin", "vmax"o uno de los siguientes:vk font size grandevk font size grandevk font size x largevk font size xx largevk font size smallvk font size smallervk font size x smallvk font size xx small | Sí | | style | text | Estilo de fuente. | vk font style italicvk font style oblique | No | | variant | text | Especifica el tipo de letra en minúsculas. | vk font variant small caps | No | | weight | text | Define el grosor de la fuente. | vk font weight 100vk font weight 200vk font weight 300vk font weight 400vk font weight 500vk font weight 600vk font weight 700vk font weight 800vk font weight 900vk font weight boldvk font weight boldervk font weight lighter | No |
Este objeto puede crearse con el comando VP Font to object.
La cadena abreviada devuelta puede asignarse a la propiedad "fuente" de una celda con la función VP SET CELL STYLE, por ejemplo.
$cellStyle:=VP Get cell style($range)
$font:=VP Font to object($cellStyle.font)
$font.style:=vk font style oblique
$font.variant:=vk font variant small caps
$font.weight:=vk font weight bolder
$cellStyle.font:=VP Object to font($font)
//$cellStyle.font contiene "bolder oblique small-caps 16pt arial"
4D View Pro Style Objects and Style Sheets
VP Font to object
VP SET CELL STYLE
VP SET DEFAULT STYLE
Historia
| Lanzamiento | Modificaciones |
|---|
| 19 R4 | Añadidos |
VP PASTE FROM OBJECT ( rangeObj : Object ; dataObject : Object {; options : Integer} )
| Parámetros | Tipo | | Descripción |
|---|
| rangeObj | Object | -> | Objeto de rango de celda | | dataObject | Object | -> | Objeto que contiene los datos a pegar | | options | Integer | -> | Especifica lo que se pega |
El comando VP PASTE FROM OBJECT pega el contenido, estilo y fórmulas almacenadas en dataObject al objeto rangeObj.
En rangeObj pase el objeto rango de celdas donde se pegarán los valores, el formato y/o las celdas de la fórmula. Si rangeObj se refiere a más de una celda, sólo se utiliza la primera.
En dataObject, pase el objeto que contiene los datos de la celda, el formato y las fórmulas a pegar.
En el parámetro opcional options, puede especificar qué pegar en el rango de celdas. Valores posibles:
|Constante|Descripción|
|---|---|---|
|vk clipboard options all|Pega todos los objetos de datos, incluyendo valores, formato y fórmulas.|
|vk clipboard options formatting|Pega solo el formato.|
|vk clipboard options formulas|Pega solo las fórmulas.|
|vk clipboard options formulas and formatting|Pega fórmulas y formato.|
|vk clipboard options values|Pega solo valores.|
|vk clipboard options value and formatting|Pega valores y formato.|
Se tienen en cuenta las opciones de pegado definidas en las opciones del libro de trabajo.
Si options se refiere a una opción de pegado que no está presente en el objeto copiado (por ejemplo, fórmulas), el comando no hace nada.
Ver el ejemplo de VP Copy to object
VP Copy to object
VP MOVE CELLS
VP Get workbook options
VP SET WORKBOOK OPTIONS
VP PRINT ( vpAreaName : Text { ; sheet : Integer } )
| Parámetros | Tipo | | Descripción |
|---|
| vpAreaName | Text | -> | Nombre de objeto formulario área 4D View Pro | | sheet | Integer | -> | Índice de la hoja (hoja actual si se omite) |
El comando VP PRINT abre una ventana de diálogo de impresión para imprimir vpAreaName.
Pase el área 4D View Pro a imprimir en vpAreaName. El comando abrirá la ventana de diálogo de impresión del sistema donde se puede definir la impresora y las propiedades de la página.
Las propiedades definidas en la ventana de diálogo de impresión son para el papel de la impresora, no son las propiedades de impresión para el área 4D View Pro. Las propiedades de impresión para áreas 4D View Pro se definen utilizando el comando VP SET PRINT INFO. Se recomienda encarecidamente que las propiedades de la impresora y del área 4D View Pro coincidan, de lo contrario el documento impreso podría no corresponder a sus expectativas.
En el parámetro opcional sheet, puede designar una hoja específica a imprimir (la numeración comienza en 0). Si se omite, la hoja actual se utiliza por defecto. Puedes seleccionar explícitamente la hoja de cálculo actual o todo el libro de trabajo con las siguientes constantes:
vk current sheetvk workbook
- Las áreas 4D View Pro sólo pueden imprimirse con el comando
VP PRINT.
- Los comandos del tema de lenguaje 4D Impresión no son compatibles con
VP PRINT.
- Este comando está destinado a la impresión individual por parte del usuario final. Para trabajos de impresión automatizados, se aconseja exportar el área 4D View Pro como PDF con el método VP EXPORT DOCUMENT.
El código siguiente:
... abrirá una ventana de diálogo de impresión:
VP EXPORT DOCUMENT
VP SET PRINT INFO
VP RECOMPUTE FORMULAS ( vpAreaName : Text )
| Parámetros | Tipo | | Descripción |
|---|
| vpAreaName | Text | -> | Nombre de objeto formulario área 4D View Pro |
El comando VP RECOMPUTE FORMULAS evalúa inmediatamente todas las fórmulas en vpAreaName. Por defecto, 4D calcula automáticamente las fórmulas cuando se insertan, importan o exportan. VP RECOMPUTE FORMULAS permite forzar el cálculo en cualquier momento (por ejemplo, en caso de que se realicen modificaciones en las fórmulas o si éstas contienen llamadas a la base). El comando lanza la ejecución del comando VP FLUSH COMMANDS para ejecutar cualquier comando almacenado y limpiar el buffer de comandos, luego calcula todas las fórmulas del libro de trabajo.
En vpAreaName, pase el nombre del área 4D View Pro. Si pasa un nombre que no existe, se devuelve un error.
Asegúrese de que el comando VP SUSPEND COMPUTING no ha sido ejecutado previamente utilizando VP RECOMPUTE FORMULAS, de lo contrario el comando no hace nada.
Para refrescar todas las fórmulas del libro de trabajo:
VP RECOMPUTE FORMULAS("ViewProArea")
VP RESUME COMPUTING
VP SUSPEND COMPUTING
VP REMOVE NAME ( vpAreaName : Text ; name : Text { ; scope : Integer } )
| Parámetros | Tipo | | Descripción |
|---|
| vpAreaName | Text | -> | Nombre de objeto formulario área 4D View Pro | | name | Text | -> | Nombre del rango nombrado o fórmula nombrada a eliminar | | scope | Integer | -> | Alcance objetivo (por defecto=hoja actual) |
El comando VP REMOVE NAME elimina el rango con nombre o la fórmula con nombre pasada en el parámetro name en el scope definido.
En vpAreaName, pase el nombre del área 4D View Pro. Si pasa un nombre que no existe, se devuelve un error.
Pase el rango con nombre o la fórmula con nombre que desea eliminar en name.
Puede definir dónde eliminar el nombre en scope utilizando el índice de la hoja (la numeración comienza en 0) o una de las siguientes constantes:
vk current sheetvk workbook
$range:=VP Cell("ViewProArea";0;0)
VP ADD RANGE NAME("Total1";$range)
VP REMOVE NAME("ViewProArea";"Total1")
$formula:=VP Get formula by name("ViewProArea";"Total1")
//$formula=null
VP Name
VP REMOVE SHEET ( vpAreaName : Text ; index: Integer )
| Parámetros | Tipo | | Descripción |
|---|
| vpAreaName | Text | -> | Nombre de objeto formulario área 4D View Pro | | index | Integer | -> | Índice de la hoja a eliminar |
VP ADD SHEET
El comando VP REMOVE SHEET elimina la hoja con el index especificado del documento cargado en vpAreaName.
En vpAreaName, pase el nombre del área 4D View Pro.
En index, pase el índice de la hoja que desea eliminar. Si el index pasado no existe, el comando no hace nada.
La indexación comienza en 0.
El documento tiene actualmente tres hojas:
Eliminar la tercera hoja:
VP REMOVE SHEET("ViewProArea";2)
VP REMOVE SPAN ( rangeObj : Object )
| Parámetros | Tipo | | Descripción |
|---|
| rangeObj | Object | -> | Objeto rango |
El comando VP REMOVE SPAN remueve el span de las celdas en rangeObj.
En rangeObj, pase un objeto rango de la fusión. Las celdas fusionadas en el rango se dividen en celdas individuales.
Para eliminar todas las fusiones de celdas de este documento:
//identifica todas las celdas fusionadas
$span:=VP Get spans(VP All("ViewProArea"))
//eliminar las fusiones
VP REMOVE SPAN($span)
Resultado:
VP ADD SPAN
VP Get spans
VP REMOVE STYLESHEET ( vpAreaName : Text ; styleName : Text { ; sheet : Integer } )
| Parámetros | Tipo | | Descripción |
|---|
| vpAreaName | Text | -> | Nombre de objeto formulario área 4D View Pro | | styleName | Text | -> | Nombre del estilo a eliminar | | sheet | Integer | -> | Índice de la hoja (hoja actual si se omite) |
El comando VP REMOVE STYLESHEET elimina la hoja de estilo pasada en el styleName del vpAreaName.
En vpAreaName, pase el nombre del área 4D View Pro. Si pasa un nombre que no existe, se devuelve un error.
Pase la hoja de estilo a eliminar en el parámetro styleName.
Puede definir dónde eliminar el estilo en el parámetro opcional sheet utilizando el índice de la hoja (la numeración comienza en 0) o con las siguientes constantes:
vk current sheetvk workbook
Para eliminar el objeto estilo GreenDashDotStyle de la hoja actual:
VP REMOVE STYLESHEET("ViewProArea";"GreenDashDotStyle")
VP ADD STYLESHEET
VP Get stylesheet
VP Get stylesheets
Historia
| Lanzamiento | Modificaciones |
|---|
| 19 R6 | Añadidos |
VP REMOVE TABLE ( vpAreaName : Text; tableName : Text {; options : Integer} {; sheet : Integer} )
| Parámetros | Tipo | | Descripción |
|---|
| vpAreaName | Text | -> | Nombre del área View Pro | | tableName | Text | -> | Nombre de la tabla a eliminar | | options | Integer | -> | Opciones adicionales | | sheet | Integer | -> | Índice de la hoja (hoja actual si se omite) |
El comando VP REMOVE TABLE elimina una tabla que haya creado con VP CREATE TABLE.
En vpAreaName, pase el nombre del área donde se encuentra la tabla a eliminar.
En tableName, pase el nombre de la tabla a eliminar.
En options, puede especificar comportamientos adicionales. Los valores posibles son:
| Constante | Valor | Descripción |
|---|
| vk table remove all | 0 | Eliminar todos los estilos y datos incluidos | | vk table remove style | 1 | Eliminar estilo pero mantener datos | | vk tabla eliminar datos | 2 | Eliminar datos pero mantener el estilo |
Los nombres de tablas se definen a nivel de la hoja. Puede especificar dónde se encuentra la tabla utilizando el parámetro opcional sheet (la indexación comienza en 0).
Para eliminar la tabla "people" en la segunda hoja y mantener los datos en las celdas:
VP REMOVE TABLE("ViewProArea"; "people"; vk table remove style; 2)
VP CREATE TABLE
Historia
| Lanzamiento | Modificaciones |
|---|
| 19 R7 | Añadidos |
VP REMOVE TABLE COLUMNS ( vpAreaName : Text ; tableName : Text ; column : Integer {; count : Integer {; sheet : Integer }} )
| Parámetros | Tipo | | Descripción |
|---|
| vpAreaName | Text | -> | Nombre de objeto formulario área 4D View Pro | | tableName | Text | -> | Table name | | column | Integer | -> | Índice en la tabla de la columna inicial a eliminar | | count | Text | -> | Número de columnas a eliminar (debe ser >0) | | sheet | Integer | -> | Índice de la hoja (hoja actual si se omite) |
El comando VP REMOVE TABLE COLUMNS elimina una o count columna(s) en el tableName especificado en el índice column especificado. El comando elimina valores y estilos.
El comando elimina las columnas de la tabla tableName, NO de la hoja. El número total de columnas de la hoja no se ve afectado por el comando. El número total de columnas de la hoja no se ve afectado por el comando.
Si tableName no existe, no pasa nada.
Para eliminar dos columnas de la tercera columna de la tabla "dataTable":
VP REMOVE TABLE COLUMNS("ViewProArea"; "dataTable"; 3; 2)
VP INSERT TABLE COLUMNS
VP REMOVE TABLE ROWS
Historia
| Lanzamiento | Modificaciones |
|---|
| 19 R7 | Añadidos |
VP REMOVE TABLE ROWS ( vpAreaName : Text ; tableName : Text ; row : Integer {; count : Integer {; sheet : Integer }} )
| Parámetros | Tipo | | Descripción |
|---|
| vpAreaName | Text | -> | Nombre de objeto formulario área 4D View Pro | | tableName | Text | -> | Table name | | row | Integer | -> | Índice en la tabla de la línea inicial a eliminar | | count | Text | -> | Número de líneas a eliminar (debe ser >0) | | sheet | Integer | -> | Índice de la hoja (hoja actual si se omite) |
El comando VP REMOVE TABLE ROWS elimina una o count fila(s) del tableName especificado en el índice row especificado. El comando elimina valores y estilos.
Este comando elimina las líneas de la tabla tableName, NO de la hoja. El número total de líneas de la hoja no se ve afectado por el comando. El número total de líneas de la hoja no se ve afectado por el comando.
Si la tabla tableName está vinculada a un contexto de datos, el comando elimina elemento(s) de la colección.
Si tableName no existe, no pasa nada.
Para eliminar dos líneas de la tercera línea de la tabla "dataTable":
VP REMOVE TABLE ROWS("ViewProArea"; "dataTable"; 3; 2)
VP INSERT TABLE ROWS
VP REMOVE TABLE COLUMNS
VP RESET SELECTION ( vpAreaName : Text { ; sheet : Integer } )
| Parámetros | Tipo | | Descripción |
|---|
| vpAreaName | Text | -> | Nombre de objeto formulario área 4D View Pro | | sheet | Integer | -> | Índice de la hoja (hoja actual si se omite) |
El comando VP RESET SELECTION deselecciona todas las celdas, con lo que no hay selección actual ni celda activa visible.
Una celda activa por defecto (celda A1) permanece definida para los comandos 4D View Pro.
En vpAreaName, pase el nombre del área 4D View Pro. Si pasa un nombre que no existe, se devuelve un error.
En el parámetro opcional sheet, puede designar una hoja específica donde se definirá el rango (la numeración comienza en 0). Si se omite, se utiliza por defecto la hoja de cálculo actual. Puede seleccionar explícitamente la hoja de cálculo actual con la siguiente constante:
Desea deseleccionar todas las celdas (la celda activa y cualquier otra celda seleccionada):
VP RESET SELECTION("myVPArea")
VP ADD SELECTION
VP Get active cell
VP Get selection
VP SET ACTIVE CELL
VP SET SELECTION
VP SHOW CELL
Historia
| Lanzamiento | Modificaciones |
|---|
| 19 R7 | Añadidos |
VP RESIZE TABLE ( rangeObj : Object; tableName : Text )
| Parámetros | Tipo | | Descripción |
|---|
| rangeObj | Object | -> | Nuevo rango para la tabla | | tableName | Text | -> | Nombre de la tabla |
El comando VP RESIZE TABLE cambia el tamaño de tableName con respecto al rangeObj.
Se aplican las siguientes reglas:
- Los encabezados deben permanecer en la misma línea y el rango de la tabla resultante debe superponerse al rango de la tabla original.
- Si el conteo de líneas de la tabla redimensionada es inferior al conteo de líneas inicial, los valores dentro de las líneas o columnas recortadas se mantienen si no estaban vinculados a un contexto de datos, de lo contrario se eliminan.
- Si la tabla se expande en las celdas que contienen datos:
- si se añaden líneas, se eliminan datos,
- si se añaden columnas, los datos se mantienen y se muestran en nuevas columnas.
Si tableName no existe, no pasa nada.
Usted crea una tabla con un contexto de datos:
var $context : Object
$context:=New object()
$context.col:=New collection
$context.col.push(New object("name"; "Smith"; "salary"; 10000))
$context.col.push(New object("name"; "Wesson"; "salary"; 50000))
$context.col.push(New object("name"; "Gross"; "salary"; 10500))
VP SET DATA CONTEXT("ViewProArea"; $context)
VP CREATE TABLE(VP Cells("ViewProArea"; 1; 1; 3; 3); "PeopleTable"; "col")
Quiere añadir una columna antes y después de la tabla, así como dos líneas vacías. Puede escribir:
VP RESIZE TABLE(VP Cells("ViewProArea"; 0; 1; 4; 6); "PeopleTable")
VP CREATE TABLE
VP Get table range
VP RESUME COMPUTING ( vpAreaName : Text )
| Parámetros | Tipo | | Descripción |
|---|
| vpAreaName | Text | -> | Nombre de objeto formulario área 4D View Pro |
El comando VP RESUME COMPUTING reinicia el cálculo de las fórmulas en vpAreaName.
El comando reactiva el servicio de cálculo de 4D View Pro. Se actualizan las fórmulas impactadas por los cambios realizados mientras los cálculos eran suspendidos, y se calculan las fórmulas añadidas después de ejecutar VP RESUME COMPUTING.
En vpAreaName, pase el nombre del área 4D View Pro. Si pasa un nombre que no existe, se devuelve un error.
El servicio de cálculo de 4D View Pro mantiene un contador de acciones de suspensión/reanudación. Por lo tanto, cada ejecución de VP RESUME COMPUTING debe equilibrarse con una ejecución correspondiente del comando VP SUSPEND COMPUTING.
Ver ejemplo en VP SUSPEND COMPUTING.
VP RECOMPUTE FORMULAS
VP SUSPEND COMPUTING
VP Row ( vpAreaName : Text; row : Integer { ; rowCount : Integer { ; sheet : Integer } } ) : Object
| Parámetros | Tipo | | Descripción |
|---|
| vpAreaName | Text | -> | Nombre de objeto formulario área 4D View Pro | | row | Integer | -> | Índice de la línea | | rowCount | Integer | -> | Número de líneas | | sheet | Integer | -> | Índice de la hoja (hoja actual si se omite) | | Resultado | Object | <- | Rango de línea(s) |
El comando VP Row devuelve un nuevo objeto de rango que hace referencia a una fila o filas específicas.
En vpAreaName, pase el nombre del área 4D View Pro. Si pasa un nombre que no existe, se devuelve un error.
El parámetro row define la primera fila del rango de filas. Pase el índice de la línea (el conteo comienza en 0) en este parámetro. Pase el índice de la línea (el conteo comienza en 0) en este parámetro.
El parámetro opcional rowCount permite definir el número total de líneas del rango. rowCount debe ser mayor que 0. Si se omite, el valor será 1 por defecto.
En el parámetro opcional sheet, puede designar una hoja específica donde se definirá el rango (la numeración comienza en 0). Si no se especifica, se utiliza por defecto la hoja de cálculo actual. Puede seleccionar explícitamente la hoja de cálculo actual con la siguiente constante:
Desea definir un objeto rango para la línea que se muestra a continuación (en la hoja de cálculo actual):
Puede escribir:
$row:=VP Row("ViewProArea";9) // línea 10
VP All
VP Cell
VP Cells
VP Column
VP Combine ranges
VP Name
VP ROW AUTOFIT ( rangeObj : Object)
| Parámetros | Tipo | | Descripción |
|---|
| rangeObj | Object | -> | Objeto rango |
El comando VP ROW AUTOFIT dimensiona automáticamente la(s) fila(s) de rangeObj en función de su contenido.
En rangeObj, pase un objeto rango que contenga un rango de líneas cuyo tamaño se gestionará automáticamente.
Las siguientes líneas no muestran correctamente el texto:
VP ROW AUTOFIT(VP Row("ViewProArea";1;2))
Resultado:
VP Column autofit
VP Run offscreen area ( parameters : Object) : Mixed
| Parámetros | Tipo | | Descripción |
|---|
| parameters | Object | -> | Objeto que contiene los atributos del área fuera de pantalla | | Resultado | Mixed | <- | propiedad .result del objeto .onEvent, o Null si no devuelve ningún valor |
El comando VP Run offscreen area crea un área fuera de pantalla en la memoria que puede ser utilizada para procesar comandos y funciones del área 4D View Pro.
En el objeto parameters, pase una de las siguientes propiedades opcionales. Estas propiedades estarán disponibles a través del comando This dentro del método onEvent y harán referencia a la instancia:
| Propiedad | Tipo | Descripción |
|---|
| area | text | El nombre del área fuera de la pantalla. Si se omite o es null, se asigna un nombre genérico (por ejemplo, "OffscreenArea1"). | | onEvent | objet (fórmula) | Un método retro llamada que se lanzará cuando el área fuera de la pantalla esté lista. Puede ser: una función onEvent de una clase, o unobjeto Formula Pordefecto, el método de retrollamada es llamado en los eventos On VP Ready, On Load, On Unload, On End URL Loading, On URL Loading Error, On VP Range Changed, u On Timer. El método de retrollamada puede ser utilizado para acceder a la variable del objeto 4D View Pro. | | autoQuit | boolean | True (valor por defecto) si el comando debe detener la ejecución de la fórmula cuando se produzcan los eventos On End URL Loading o On URL Loading Error. Si es false, debe utilizar los comandos CANCEL o ACCEPT en el método de retrollamada onEvent. | | timeout | number | Tiempo máximo (expresado en segundos) antes de que el área se cierre automáticamente si no se genera ningún evento. Si se fija en 0, no se aplica ninguna limitación. Valor por defecto: 60 | | resultado | mixto | Resultado del procesamiento (si hay) | <customProperty> | mixto | Todo atributo personalizado que esté disponible en el método de retrollamada onEvent. |
La siguiente propiedad es añadida automáticamente por el comando si es necesario:
| Propiedad | Tipo | Descripción |
|---|
| timeoutReached | boolean | Añadido con el valor true si se ha excedido el tiempo de espera |
El área fuera de pantalla solo está disponible durante la ejecución del comando VP Run offscreen area. Se destruirá automáticamente una vez finalizada la ejecución.
Los siguientes comandos se pueden utilizar en el método de retrollamada:
ACCEPTCANCELSET TIMERWA Evaluate JavaScriptWA EXECUTE JAVASCRIPT FUNCTION
Quiere crear un área 4D View Pro fuera de la pantalla y obtener el valor de una celda:
// cs.OffscreenArea class declaration
Class constructor ($path : Text)
This.filePath:=$path
// This function will be called on each event of the offscreen area
Function onEvent()
Case of
:(FORM Event.code=On VP Ready)
VP IMPORT DOCUMENT(This.area;This.filePath)
This.result:=VP Get value(VP Cell(This.area;6;22))
ALERT("The G23 cell contains the value: "+String(This.result))
End case
El método de retrollamada OffscreenArea:
$o:=cs.OffscreenArea.new()
$result:=VP Run offscreen area($o)
Quiere cargar un documento grande fuera de la pantalla, esperar a que todos los cálculos se completen y exportarlo como PDF:
//cs.OffscreenArea class declaration
Class constructor($pdfPath : Text)
This.pdfPath:=$pdfPath
This.autoQuit:=False
This.isWaiting:=False
Function onEvent()
Case of
:(FORM Event.code=On VP Ready)
// Document import
VP IMPORT DOCUMENT(This.area;$largeDocument4VP)
This.isWaiting:=True
// Start a timer to verify if all calculations are finished.
// If during this period the "On VP Range Changed" is thrown, the timer will be restarted
// The time must be defined according to the computer configuration.
SET TIMER(60)
:(FORM Event.code=On VP Range Changed)
// End of calculation detected. Restarts the timer
If(This.isWaiting)
SET TIMER(60)
End if
:(FORM Event.code=On Timer)
// To be sure to not restart the timer if you call others 4D View command after this point
This.isWaiting:=False
// Stop the timer
SET TIMER(0)
// Start the PDF export
VP EXPORT DOCUMENT(This.area;This.pdfPath;New object("formula";Formula(ACCEPT)))
:(FORM Event.code=On URL Loading Error)
CANCEL
End case
El método de retrollamada OffscreenArea:
$o:=cs.OffscreenArea.new()
$result:=VP Run offscreen area($o)
Blog post: End of document loading
VP SET ACTIVE CELL ( rangeObj : Object)
| Parámetros | Tipo | | Descripción |
|---|
| rangeObj | Object | -> | Objeto rango |
El comando VP SET ACTIVE CELL define una célula especificada como activa.
En rangeObj, pase un rango que contenga una única celda como objeto (ver VP Cell). Si rangeObj no es un rango de celdas o contiene varios rangos, se utiliza la primera celda del primer rango.
Para definir la celda de la columna D, línea 5 como celda activa:
$activeCell:=VP Cell("myVPArea";3;4)
VP SET ACTIVE CELL($activeCell)
VP ADD SELECTION
VP Get active cell
VP Get selection
VP RESET SELECTION
VP SET SELECTION
VP SHOW CELL
VP SET ALLOWED METHODS ( methodObj : Object)
| Parámetros | Tipo | | Descripción |
|---|
| methodObj | Object | -> | Métodos permitidos en las áreas 4D View Pro |
Compatibilidad
For greater flexiblity, it is recommended to use the VP SET CUSTOM FUNCTIONS command which allows you to designate 4D formulas that can be called from 4D View Pro areas. En cuanto se llama a VP SET CUSTOM FUNCTIONS, se ignoran las llamadas a VP SET ALLOWED METHODS. 4D View Pro también soporta el comando genérico 4D SET ALLOWED METHODS si no se llama ni a VP SET CUSTOM FUNCTIONS ni a VP SET ALLOWED METHODS, sin embargo no se recomienda usar el comando genérico.
El comando VP SET ALLOWED METHODS designa los métodos proyecto que pueden ser llamados en las fórmulas 4D View Pro. Este comando se aplica a todas las áreas 4D View Pro inicializadas después de su llamada durante la sesión. Se puede llamar varias veces en la misma sesión para inicializar diferentes configuraciones.
Por defecto, por razones de seguridad, si no se ejecuta el comando VP SET ALLOWED METHODS, no se permite ninguna llamada a métodos en las áreas 4D View Pro -- excepto si se ha utilizado el comando genérico SET ALLOWED METHODS (ver nota de compatibilidad). El uso de un método no autorizado en una fórmula muestra un error #NAME? El uso de un método no autorizado en una fórmula muestra un error #NAME? error en el área 4D View Pro.
En el parámetro methodObj, pase un objeto en el que cada propiedad es el nombre de una función a definir en las áreas 4D View Pro:
| Propiedad | | | Tipo | Descripción |
|---|
<functionName> | | | Object | Definición de la función personalizada. El nombre de la propiedad <functionName> define el nombre de la función personalizada que se mostrará en las fórmulas 4D View Pro (no se permiten espacios) | | method | | Text | (obligatorio) Nombre del método proyecto 4D existente a autorizar | | parameters | | Colección de objetos | Colección de parámetros (en el orden en que están definidos en el método). | | | [ ].name | Text | Nombre de un parámetro a mostrar para la <functionName>.Nota: los nombres de los parámetros no deben contener caracteres de espacio. | | | [ ].type | Number | Tipo de parámetro. Supported types:Is BooleanIs dateIs IntegerIs objectIs realIs textIs timeIf omitted, by default the value is automatically sent with its type, except date or time values which are sent as an object (see Parameters section). Si type es Is object, el objeto tiene la misma estructura que el objeto devuelto por VP Get value. | | summary | | Text | Descripción de la función a mostrar en 4D View Pro | | minParams | | Number | Número mínimo de parámetros | | maxParams | | Number | Número máximo de parámetros. Pasar un número superior a la longitud de los parámetros permite declarar parámetros "opcionales" con tipo por defecto |
Usted quiere autorizar dos métodos en sus áreas 4D View Pro:
var $allowed : Object
$allowed:=New object //parámetro para el comando
$allowed.Hello:=New object //crea una primera función simple llamada "Hello"
$allowed.Hello.method:="My_Hello_Method" //define el método 4D
$allowed.Hello.summary:="Hello prints hello world"
$allowed.Byebye:=New object //crea una segunda función con parámetros llamada "Byebye"
$allowed.Byebye.method:="My_ByeBye_Method"
$allowed.Byebye.parameters:=New collection
$allowed.Byebye.parameters.push(New object("name";"Message";"type";Is text))
$allowed.Byebye.parameters.push(New object("name";"Date";"type";Is date))
$allowed.Byebye.parameters.push(New object("name";"Time";"type";Is time))
$allowed.Byebye.summary:="Byebye prints a custom timestamp"
$allowed.Byebye.minParams:=3
$allowed.Byebye.maxParams:=3
VP SET ALLOWED METHODS($allowed)
Una vez ejecutado este código, las funciones definidas pueden utilizarse en las fórmulas 4D View Pro:
En las fórmulas 4D View Pro, los nombres de las funciones se muestran automáticamente en mayúsculas.
4D functions
VP SET CUSTOM FUNCTIONS
Historia
| Lanzamiento | Modificaciones |
|---|
| 19 R5 | Añadidos |
VP SET BINDING PATH ( rangeObj : Object ; dataContextAttribute : Text)
| Parámetros | Tipo | | Descripción |
|---|
| rangeObj | Object | -> | Objeto rango | | dataContextAttribute | Text | -> | Nombre del atributo a vincular a rangeObj |
El comando VP SET BINDING PATH vincula un atributo del contexto de datos de una hoja a rangeObj. Después de definir un contexto de datos utilizando el método SET DATA CONTEXT. Cuando se carga, si el contexto de datos contiene el atributo, el valor de dataContextAttribute se muestra automáticamente en las celdas en rangeObj.
En rangeObj, pase un objeto que es un rango de celdas o un rango combinado de celdas.
- Si rangeObj es un rango con varias celdas, el comando vincula el atributo a la primera celda del rango.
- Si rangeObj contiene varios rangos de celdas, el comando vincula el atributo a la primera celda de cada rango.
En dataContextAttribute, pase el nombre del atributo a vincular a rangeObj. Si dataContextAttribute es una cadena vacía, la función elimina el enlace actual.
Los atributos de tipo colección no están soportados. Cuando se pasa el nombre de un atributo de la colección, el comando no hace nada.
Define un contexto de datos y vincula el atributo firstNamey lastNamea las celdas:
var $p : Object
$p:=New object
$p.firstName:="Freehafer"
$p.lastName:="Nancy"
VP SET DATA CONTEXT("ViewProArea"; $p)
VP SET BINDING PATH(VP Cell("ViewProArea"; 0; 0); "firstName")
VP SET BINDING PATH(VP Cell("ViewProArea"; 1; 0); "lastName")
VP Get binding path
VP Get data context
VP SET DATA CONTEXT
VP SET BOOLEAN VALUE ( rangeObj : Object ; boolValue : Boolean)
| Parámetros | Tipo | | Descripción |
|---|
| rangeObj | Object | -> | Objeto rango | | boolValue | Boolean | -> | Valor del booleano a definir |
El comando VP SET BOOLEAN VALUE asigna un valor booleano especificado a un rango de celdas designado.
En rangeObj, pase un rango de la(s) celda(s) (creadas, por ejemplo, con VP Cell o VP Column) cuyo valor desea especificar. Si rangeObj incluye varias celdas, el valor especificado se repetirá en cada una de ellas.
El parámetro boolValue permite pasar el valor booleano (True o False) que se asignará al rangeObj.
//Establecer el valor de la celda como False
VP SET BOOLEAN VALUE(VP Cell("ViewProArea";3;2);False)
VP SET VALUE
VP SET BORDER ( rangeObj : Object ; borderStyleObj : Object ; borderPosObj : Objeto )
| Parámetros | Tipo | | Descripción |
|---|
| rangeObj | Object | -> | Objeto rango | | borderStyleObj | Object | -> | Objeto que contiene el estilo de línea de borde | | borderPosObj | Object | -> | Objeto que contiene la posición del borde |
El comando VP SET BORDER aplica los estilos de borde definidos en borderStyleObj y borderPosObj al rango definido en rangeObj.
En rangeObj, pase un rango de celdas donde se aplicará el estilo de borde. Si rangeObj contiene múltiples celdas, los bordes aplicados con VP SET BORDER se aplicarán al rangeObj como un todo (a diferencia del comando VP SET CELL STYLE que aplica bordes a cada celda del rangeObj). Si ya se ha aplicado una hoja de estilo, VP SET BORDER anulará la configuración de bordes aplicada anteriormente para el rangeObj.
El parámetro borderStyleObj permite definir el estilo de las líneas del borde. borderStyleObj soporta las siguientes propiedades:
| Propiedad | Tipo | Descripción | Valores posibles |
|---|
| color | text | Define el color del borde. . | Sintaxis de color CSS "#rrggbb" (sintaxis preferida), sintaxis de color CSS "rgb(r,g,b)" (sintaxis alternativa), nombre de color CSS (sintaxis alternativa) | | style | Integer | Define el estilo del borde. . | vk line style dash dotvk line style dash dot dotvk line style dashed vk line style dottedvk line style doublevk line style emptyvk line style hair vk line style mediumvk line style medium dash dotvk line style medium dash dot dotvk line style medium dashedvk line style slanted dash dotvk line style thickvk line style thin |
Puede definir la posición del borderStyleObj (es decir, dónde se aplica la línea) con el borderPosObj:
| Propiedad | Tipo | Descripción |
|---|
| all | boolean | Estilo de la línea de borde aplicado a todos los bordes. | | left | boolean | Estilo de la línea de borde aplicado al borde izquierdo. | | top | boolean | Estilo de la línea de borde aplicado al borde superior. | | right | boolean | Estilo de la línea de borde aplicado al borde derecho. | | bottom | boolean | Estilo de la línea de borde aplicado al borde inferior. | | outline | boolean | Estilo de línea de borde aplicado únicamente a los bordes exteriores. | | inside | boolean | Estilo de la línea de borde aplicado únicamente a los bordes interiores. | | innerHorizontal | boolean | Estilo de la línea de borde aplicado únicamente a los bordes horizontales interiores. | | innerVertical | boolean | Estilo de la línea de borde aplicado sólo a los bordes verticales interiores. |
Este código produce un borde alrededor de todo el rango:
$border:=New object("color";"red";"style";vk line style thick)
$option:=New object("outline";True)
VP SET BORDER(VP Cells("ViewProArea";1;1;3;3);$border;$option)
Este código demuestra la diferencia entre VP SET BORDER y la definición de bordes con el comando VP SET CELL STYLE:
// Definir los bordes con VP SET BORDER
$border:=New object("color";"red";"style";vk line style thick)
$option:=New object("outline";True)
VP SET BORDER(VP Cells("ViewProArea";1;1;3;3);$border;$option)
// // Definir los bordes con VP SET CELL STYLE
$cellStyle:=New object
$cellStyle.borderBottom:=New object("color";"blue";"style";vk line style thick)
$cellStyle.borderRight:=New object("color";"blue";"style";vk line style thick)
VP SET CELL STYLE(VP Cells("ViewProArea";4;4;3;3);$cellStyle)
VP SET CELL STYLE
VP SET CELL STYLE ( rangeObj : Object ; styleObj : Object)
| Parámetros | Tipo | | Descripción |
|---|
| rangeObj | Object | -> | Objeto rango | | styleObj | Object | -> | Objeto style |
El comando VP SET CELL STYLE aplica el estilo o estilos definidos en el styleObj a las celdas definidas en el rangeObj.
En rangeObj, pase un rango de celdas donde se aplicará el estilo. Si rangeObj contiene múltiples celdas, el estilo se aplica a cada celda.
Los bordes aplicados con VP SET CELL STYLE se aplicarán a cada celda del rangeObj, a diferencia del comando VP SET BORDER que aplica bordes al rangeObj en su conjunto.
El parámetro styleObj permite pasar un objeto que contiene propiedades de estilo. Puede utilizar una hoja de estilo existente o crear una nueva. Puede utilizar una hoja de estilo existente o crear una nueva.
Para eliminar un estilo y volver a la configuración de estilo por defecto (si la hay), pase un valor NULL:
- dar al parámetro styleObj un valor NULL eliminará toda configuración de estilo del rangeObj,
- si se le da a un atributo un valor NULL, se eliminará este atributo específico de rangeObj.
Para obtener más información sobre los objetos de estilo y las hojas de estilo, consulte el párrafo Objetos de estilo.
$style:=New object
$style.font:="8pt Arial"
$style.backColor:="Azure"
$style.foreColor:="red"
$style.hAlign:=1
$style.isVerticalText:=True
$style.borderBottom:=New object("color";"#800080";"style";vk line style thick)
$style.backgroundImage:=Null //eliminar un atributo específico
VP SET CELL STYLE(VP Cell("ViewProArea";1;1);$style)
VP ADD STYLESHEET
VP Font to object
VP Get cell style
VP Object to font
VP SET BORDER
VP SET DEFAULT STYLE
VP SET COLUMN ATTRIBUTES ( rangeObj : Object ; propertyObj : Object)
| Parámetros | Tipo | | Descripción |
|---|
| rangeObj | Object | -> | Objeto rango | | propertyObj | Object | -> | Objeto que contiene las propiedades de columna |
El comando VP SET COLUMN ATTRIBUTES aplica los atributos definidos en propertyObj a las columnas de rangeObj.
En rangeObj, pase un objeto que contenga un rango. Si el rango contiene tanto columnas como líneas, los atributos se aplican sólo a las columnas.
The propertyObj parameter lets you specify the attributes to apply to the rows in the rangeObj. Estos atributos son:
| Propiedad | Tipo | Descripción |
|---|
| ancho | number | Ancho de columna expresado en píxeles | | pageBreak | boolean | True para insertar un salto de página antes de la primera columna del rango, si no, false | | visible | boolean | True si la columna es visible, si no, false | | redimensionable | boolean | True si la columna puede redimensionarse, si no, false | | header | text | Texto del encabezado de la columna |
Para cambiar el tamaño de la segunda columna y definir el encabezado, se escribe:
var $column; $properties : Object
$column:=VP Column("ViewProArea";1) //columna B
$properties:=New object("width";100;"header";"Hello World")
VP SET COLUMN ATTRIBUTES($column;$properties)
VP Column
VP Get column attributes
VP Get row attributes
VP SET ROW ATTRIBUTES
VP SET COLUMN COUNT ( vpAreaName : Text ; columnCount : Integer { ; sheet : Integer } )
| Parámetros | Tipo | | Descripción |
|---|
| vpAreaName | Text | -> | Nombre de objeto formulario área 4D View Pro | | columnCount | Integer | -> | Número de columnas | | sheet | Integer | -> | Índice de la hoja (hoja actual si se omite) |
El comando VP SET COLUMN COUNT define el número total de columnas en vpAreaName.
En vpAreaName, pase el nombre del área 4D View Pro. Si pasa un nombre que no existe, se devuelve un error.
Pase el número total de columnas en el parámetro columnCount. columnCount debe ser mayor que 0.
En el parámetro opcional sheet, puede designar una hoja de cálculo específica en la que se aplicará columnCount (el conteo comienza en 0). Si se omite, se utiliza por defecto la hoja de cálculo actual. Puede seleccionar explícitamente la hoja de cálculo actual con la siguiente constante:
El siguiente código define cinco columnas en el área de 4D View Pro:
VP SET COLUMN COUNT("ViewProArea";5)
VP Get column count
VP Get row count
VP SET ROW COUNT
VP SET CURRENT SHEET ( vpAreaName : Text ; sheet : Integer)
| Parámetros | Tipo | | Descripción |
|---|
| vpAreaName | Text | -> | Nombre de objeto formulario área 4D View Pro | | sheet | Integer | -> | Índice de la nueva hoja actual |
El comando VP SET CURRENT SHEET define la hoja actual en vpAreaName. La hoja actual es la hoja seleccionada en el documento.
En vpAreaName, pase el nombre del área 4D View Pro.
En sheet, pase el índice de la hoja que se va a definir como hoja actual. Si el índice pasado es inferior a 0 o supera el número de hojas, el comando no hace nada.
La indexación comienza en 0.
La hoja actual del documento es la primera hoja:
Define la hoja actual en la tercera hoja:
VP SET CURRENT SHEET("ViewProArea";2)
VP Get current sheet
VP SET CUSTOM FUNCTIONS ( vpAreaName : Text ; formulaObj : Object )
| Parámetros | Tipo | | Descripción |
|---|
| vpAreaName | Text | -> | Nombre de objeto formulario área 4D View Pro | | formulaObj | Object | -> | Objeto fórmula |
El comando VP SET CUSTOM FUNCTIONS designa las fórmulas 4D que pueden ser llamadas directamente desde las fórmulas de 4D View Pro. Dado que las funciones personalizadas no se almacenan en el documento, VP SET CUSTOM FUNCTIONS debe ejecutarse en el evento de formulario On Load.
Las fórmulas especificadas por VP SET CUSTOM FUNCTIONS aparecen en un menú emergente cuando se introduce la primera letra de su nombre. Ver la página Fórmulas y Funciones.
Si se llama varias veces a VP SET CUSTOM FUNCTIONS para la misma área, en la misma sesión, sólo se tiene en cuenta la última llamada.
Pase el nombre del área de 4D View Pro en vpAreaName. Si pasa un nombre que no existe, se devuelve un error.
En el parámetro formulaObj, pase un objeto que contenga las fórmulas 4D que pueden ser llamadas desde las fórmulas 4D View Pro así como las propiedades adicionales. Cada propiedad customFunction pasada en formulaObj se convierte en el nombre de una función en el área 4D View Pro.
| Propiedad | | | Tipo | Descripción |
|---|
<customFunction> | | | Object | Definición de la función personalizada. <customFunction> define el nombre de la función personalizada que se mostrará en las fórmulas 4D View Pro (no se permiten espacios) | | formula | | Object | Objeto fórmula 4D (obligatorio). Ver el comando Formula. | | parameters | | Colección de objetos | Colección de parámetros (en el orden en que están definidos en la fórmula) | | | [ ].name | Text | Nombre del parámetro a mostrar en 4D View Pro | | | [ ].type | Number | Tipo de parámetro. Tipos soportados:Is BooleanIs dateIs IntegerIs objectIs realIs textIs timeSi se omite type o si se pasa el valor por defecto (-1), el valor se envía automáticamente con su tipo, excepto los valores de fecha u hora que se envían como un objeto (ver la sección Parámetros).Si type es Is object, el objeto tiene la misma estructura que el objeto devuelto por VP Get value. | | summary | | Text | Descripción de la Fórmula a mostrar en 4D View Pro | | minParams | | Number | Número mínimo de parámetros | | maxParams | | Number | Número máximo de parámetros. Pasar un número superior a la longitud de los parámetros permite declarar parámetros "opcionales" con tipo por defecto |
ATENCIÓN
- En cuanto se llama a
VP SET CUSTOM FUNCTIONS, los métodos permitidos por el comando VP SET ALLOWED METHODS (si los hay) son ignorados en el área 4D View Pro.
- En cuanto se llama a
VP SET CUSTOM FUNCTIONS, las funciones basadas en los comandos SET TABLE TITLES y SET FIELD TITLES son ignoradas en el área 4D View Pro.
Desea utilizar los objetos fórmula en un área 4D View Pro para añadir números, recuperar el apellido y el género de un cliente:
Case of
:(FORM Event.code=On Load)
var $o : Object
$o:=New object
// Define la función "addnum" desde un método llamado "addnum"
$o.addnum:=New object
$o.addnum.formula:=Formula(addnum)
$o.addnum.parameters:=New collection
$o.addnum.parameters.push(New object("name";"num1";"type";Is Integer))
$o.addnum.parameters.push(New object("name";"num2";"type";Is Integer))
// Definir la función "ClientLastName" desde un campo de base
$o.ClientLastName:=New object
$o.ClientLastName.formula:=Formula([Customers]lastname)
$o.ClientLastName.summary:="Lastname of the current client"
// Definir la función "label" desde una expresión 4D con un parámetro
$o.label:=New object
$o.label.formula:=Formula(ds.Customers.get($1).label)
$o.label.parameters:=New collection
$o.label.parameters.push(New object("name";"ID";"type";Is Integer))
// Definir la función "Title" desde una variable llamada "Title"
$o.Title:=New object
$o.Title.formula:=Formula(Title)
VP SET CUSTOM FUNCTIONS("ViewProArea";$o)
End case
End case
VP SET ALLOWED METHODS
VP SET DATA CONTEXT
Historia
| Lanzamiento | Modificaciones |
|---|
| 19 R5 | Añadidos |
VP SET DATA CONTEXT ( vpAreaName : Text ; dataObj : Object {; options : Object } {; sheet : Integer} )
VP SET DATA CONTEXT ( vpAreaName : Text ; dataColl : Collection ; {options : Object } {; sheet : Integer} )
| Parámetros | Tipo | | Descripción |
|---|
| vpAreaName | Text | -> | Nombre de objeto formulario área 4D View Pro | | dataObj | Object | -> | Objeto datos a cargar en el contexto de datos | | dataColl | Collection | -> | Colección datos a cargar en el contexto de datos | | options | Object | -> | Opciones adicionales | | sheet | Integer | -> | Índice de la hoja |
El comando VP SET DATA CONTEXT define el contexto de datos de una hoja. Un contexto de datos es un objeto o una colección vinculada a una hoja de cálculo, y cuyo contenido puede utilizarse para llenar automáticamente las celdas de la hoja, ya sea utilizando una opción de autogeneración o el método VP SET BINDING PATH. Por otro lado, el comando VP Get data context puede devolver un contexto que contenga modificaciones del usuario.
En vpAreaName, pase el nombre del área 4D View Pro. Si pasa un nombre que no existe, se devuelve un error.
En dataObj o dataColl, pase un objeto o una colección que contenga los datos a cargar en el contexto de datos. Las imágenes se convierten en esquemas URI de datos.
Para pasar un valor de tiempo en dataObj o dataColl, encapsúlelo en un objeto con las siguientes propiedades (ver ejemplo 4):
| Propiedad | Tipo | Descripción |
|---|
| value | Integer, Real, Boolean, Text, Date, Null | Valor a poner en el contexto | | time | Real | Valor de tiempo (en segundos) para poner en el contexto |
En options, puede pasar un objeto que especifique las opciones adicionales. Las propiedades posibles son:
| Propiedad | Tipo | Descripción |
|---|
| reset | Object | True para restablecer el contenido de la hoja antes de cargar el nuevo contexto, False (por defecto) en caso contrario. | | autoGenerateColumns | Object | Sólo se utiliza cuando los datos son una colección. True (por defecto) para especificar que las columnas deben generarse automáticamente cuando se vincula el contexto de datos. En este caso, se aplican las siguientes reglas: - Si dataColl es una colección de objetos, los nombres de los atributos se utilizan como títulos de las columnas (ver el ejemplo 2).
- Si dataColl contiene subcolecciones de valores escalares, cada subcolección define los valores de una línea (ver el ejemplo 3). La primera subcolección determina cuántas columnas se crean.
|
En sheet, pase el índice de la hoja que recibirá el contexto de datos. Si no se pasa ningún índice, el contexto se aplica a la hoja actual.
Si exporta su documento a un objeto utilizando VP Export to object, o a un documento 4DVP utilizando VP EXPORT DOCUMENT, la opción includeBindingSource le permite copiar el contenido de los contextos actuales como valores de celda en el objeto o documento exportado. Para más detalles, consulte la descripción de esos métodos.
Pasa un objeto y vincula los datos del contexto a las celdas en la primera línea:
var $data : Object
$data:=New object
$data.firstName:="Freehafer"
$data.lastName:="Nancy"
VP SET DATA CONTEXT("ViewProArea"; $data)
VP SET BINDING PATH(VP Cell("ViewProArea"; 0; 0); "firstName")
VP SET BINDING PATH(VP Cell("ViewProArea"; 1; 0); "lastName")
Pasa una colección de objetos y genera columnas automáticamente:
var $options : Object
var $data : Collection
$data:=New collection()
$data.push(New object("firstname"; "John"; "lastname"; "Smith"))
$data.push(New object("firstname"; "Mary"; "lastname"; "Poppins"))
$options:=New object("autoGenerateColumns"; True)
VP SET DATA CONTEXT("ViewProArea"; $data; $options)
data pasado como parámetro es una colección que contiene subcolecciones. Cada subcolección define el contenido de una línea:
var $data : Collection
var $options : Object
$data:=New collection
$data.push(New collection(1; 2; 3; False; "")) // Se crean 5 columnas
$data.push(New collection) // La segunda línea está vacía
$data.push(New collection(4; 5; Null; "hello"; "world")) // La tercera línea tiene 5 valores
$data.push(New collection(6; 7; 8; 9)) // La cuarta línea tiene 4 valores
$options:=New object("autoGenerateColumns"; True)
VP SET DATA CONTEXT("ViewProArea"; $data; $options)
var $data : Collection
var $options : Object
$data:= New collection()
// Las fechas pueden pasarse como valores escalares
$data.push(New collection("Date"; Current date))
// Los valores hora deben pasarse como atributos objeto
$data.push(New collection("Time"; New object("time"; 5140)))
// Ejemplo de fecha + hora
$data.push(New collection("Date + Time"; New object("value"; Current date; "time"; 5140)))
$options:=New object("autoGenerateColumns"; True)
VP SET DATA CONTEXT("ViewProArea"; $data; $options)
Este es el resultado una vez que se generan las columnas:
VP SET BINDING PATH
VP Get binding path
VP Get data context
VP SET DATE TIME VALUE ( rangeObj : Object ; dateValue : Date ; timeValue : Time {; formatPattern : Text } )
| Parámetros | Tipo | | Descripción |
|---|
| rangeObj | Object | -> | Objeto rango | | dateValue | Fecha | -> | Valor date a definir | | timeValue | Time | -> | Valor hora a definir | | formatPattern | Text | -> | Formato del valor |
El comando VP SET DATE TIME VALUE asigna un valor especificado de fecha y hora a un rango de celdas designado.
En rangeObj, pase un rango de la(s) celda(s) (creadas, por ejemplo, con VP Cell o VP Column) cuyo valor desea especificar. Si rangeObj incluye varias celdas, el valor especificado se repetirá en cada una de ellas.
El parámetro dateValue indica un valor de fecha que se asignará a rangeObj.
El parámetro timeValue indica un valor hora (expresado en segundos) que se asignará al rangeObj.
El parámetro opcional formatPattern define un modelo para los parámetros dateValue y timeValue. Para obtener información sobre los modelos y los caracteres de formato, consulte la sección Formatos fecha y hora.
//Definir el valor de la celda como la fecha y hora actuales
VP SET DATE TIME VALUE(VP Cell("ViewProArea";6;2);Current time;Current date;vk pattern full date time)
//Definir el valor de la celda como 18 de diciembre
VP SET DATE TIME VALUE(VP Cell("ViewProArea";3;9);!2024-12-18!;?14:30:10?;vk pattern sortable date time)
4D View Pro cell format
VP SET DATE VALUE
VP SET TIME VALUE
VP SET VALUE
VP SET DATE VALUE ( rangeObj : Object ; dateValue : Date { ; formatPattern : Text } )
| Parámetros | Tipo | | Descripción |
|---|
| rangeObj | Object | -> | Objeto rango | | dateValue | Fecha | -> | Valor date a definir | | formatPattern | Text | -> | Formato del valor |
El comando VP SET DATE VALUE asigna un valor de fecha especificado a un rango de celdas designado.
En rangeObj, pase un rango de la(s) celda(s) cuyo valor desea indicar. Si rangeObj incluye varias celdas, el valor especificado se repetirá en cada una de ellas.
El parámetro dateValue indica un valor de fecha que se asignará a rangeObj.
El parámetro opcional formatPattern define un modelo para el parámetro dateValue. Pase un formato personalizado o puede utilizar una de las siguientes constantes:
| Constante | Descripción | Configuración por defecto de US |
|---|
vk pattern long date | Formato ISO 8601 para la fecha completa | "dddd, dd MMMM yyyy" | vk pattern month day | Formato ISO 8601 para el mes y el día | "MMMM dd" | vk pattern short date | Formato ISO 8601 corto para la fecha | "MM/dd/yyyy" | vk pattern year month | Formato ISO 8601 para el mes y el año | "yyyy MMMM" |
Para obtener información sobre los modelos y los caracteres de formato, consulte la sección Formatos fecha y hora.
//Definir el valor de la celda para la fecha actual
VP SET DATE VALUE(VP Cell("ViewProArea";4;2);Current date))
//Definir el valor de la celda para una fecha específica con un formato designado
VP SET DATE VALUE(VP Cell("ViewProArea";4;4);Date("12/25/94");"d/m/yy ")
VP SET DATE VALUE(VP Cell("ViewProArea";4;6);!2005-01-15!;vk pattern month day)
4D View Pro cell format
VP SET DATE TIME VALUE
VP SET VALUE
VP SET DEFAULT STYLE ( vpAreaName : Text ; styleObj : Object { ; sheet : Integer } )
| Parámetros | Tipo | | Descripción |
|---|
| vpAreaName | Text | -> | Nombre de objeto formulario área 4D View Pro | | styleObj | Object | -> | Objeto style | | sheet | Integer | -> | Índice de la hoja (por defecto = hoja actual) |
El comando VP SET DEFAULT STYLE define el estilo en el styleObj como el estilo por defecto para una sheet.
En vpAreaName, pase el nombre del área 4D View Pro. Si pasa un nombre que no existe, se devuelve un error.
El parámetro styleObj le permite pasar un objeto que contiene los parámetros de estilo. Puede utilizar una hoja de estilo existente o puede crear un nuevo estilo. Para más información, consulte el párrafo Objetos de estilo.
En el parámetro opcional sheet, puede designar una hoja específica donde se definirá el estilo. Si se omite, se utiliza por defecto la hoja de cálculo actual. Puede seleccionar explícitamente la hoja de cálculo actual con la siguiente constante:
$style:=New object
$style.hAlign:=vk horizontal align left
$style.font:="12pt papyrus"
$style.backColor:="#E6E6FA" //coleor mordado claro
VP SET DEFAULT STYLE("myDoc";$style)
VP ADD STYLESHEET
VP Font to object
VP Get default style
VP Object to font
VP SET BORDER
VP SET CELL STYLE
VP SET FIELD ( rangeObj : Object ; field : Pointer { ; formatPattern : Text } )
| Parámetros | Tipo | | Descripción |
|---|
| rangeObj | Object | -> | Objeto rango | | campo | Puntero | -> | Referencia al campo en la estructura virtual | | formatPattern | Text | -> | Formato del campo |
El comando VP SET FIELD asigna un campo virtual de base de datos 4D a un rango de celdas designado.
En rangeObj, pase un rango de la(s) celda(s) cuyo valor desea indicar. En rangeObj, pase un rango de la(s) celda(s) cuyo valor desea indicar.
El parámetro field especifica un [campo virtual] de la base de datos 4D(formulas.md#referencing-fields-using-the-virtual-structure) que se asignará a rangeObj. El nombre de la estructura virtual para el field se puede ver en la barra de fórmulas. Si alguna de las celdas de rangeObj tiene contenido, se sustituirá por field.
El parámetro opcional formatPattern define un modelo para el parámetro field. Puede pasar cualquier [formato personalizado] válido (configuring.md#cell-format).
VP SET FIELD(VP Cell("ViewProArea";5;2);->[TableName]Field)
VP SET VALUE
VP SET FORMULA ( rangeObj : Object ; formula : Text { ; formatPattern : Text } )
| Parámetros | Tipo | | Descripción |
|---|
| rangeObj | Object | -> | Objeto rango | | formula | Text | -> | Fórmula o método 4D | | formatPattern | Text | -> | Formato del campo |
El comando VP SET FORMULA asigna una fórmula especificada o un método 4D a un rango de celdas designado.
En rangeObj, pase un rango de la(s) celda(s) (creadas, por ejemplo, con VP Cell o VP Column) cuyo valor desea especificar. Si rangeObj incluye varias celdas, la fórmula especificada se vinculará en cada celda.
El parámetro formula indica un nombre de fórmula o de método 4D a asignar a rangeObj.
Si formula es una cadena, utilice el punto . como separador numérico y la coma , como separador de parámetros.
If a 4D method is used, it must be allowed with the VP SET ALLOWED METHODS command.
El formatPattern opcional define un pattern para formula.
Se elimina la fórmula en rangeObj sustituyéndola por una cadena vacía ("").
VP SET FORMULA(VP Cell("ViewProArea";5;2);"SUM($A$1:$C$10)")
Para eliminar la fórmula:
VP SET FORMULA(VP Cell("ViewProArea";5;2);"")
VP SET FORMULA($range; "SUM(A1,B7,C11)") //"," para separar los parámetros
Cell format
VP Get Formula
VP SET FORMULAS
VP SET VALUE
VP SET FORMULAS ( rangeObj : Object ; formulasCol : Collection )
| Parámetros | Tipo | | Descripción |
|---|
| rangeObj | Object | -> | Objeto de rango de celda | | formulasCol | Collection | -> | Colección de fórmulas |
El comando VP SET FORMULAS asigna una colección de fórmulas que comienzan en el rango de celdas especificado.
En rangeObj, pase un rango de la celda (creada con VP Cell) cuya fórmula desea especificar. Si rangeObj incluye varios rangos, sólo se utiliza el primer rango.
El parámetro formulasCol es una colección bidimensional:
- La colección de primer nivel contiene subcolecciones de fórmulas. Cada subcolección define una línea.
- Cada subcolección define los valores de las celdas para la línea. Los valores deben ser elementos textuales que contengan las fórmulas a asignar a las celdas.
Si la fórmula es una cadena, utilice el punto . como separador numérico y la coma , como separador de parámetros.
If a 4D method is used, it must be allowed with the VP SET ALLOWED METHODS command.
Las fórmulas de rangeObj se eliminan sustituyéndolas por una cadena vacía ("").
$formulas:=New collection
$formulas.push(New collection("MAX(B11,C11,D11)";"myMethod(G4)")) // Primera línea
$formulas.push(New collection("SUM(B11:D11)";"AVERAGE(B11:D11)")) // Segunda línea
VP SET FORMULAS(VP Cell("ViewProArea";6;3);$formulas) // Definir las celdas con las fórmulas
myMethod:
Para eliminar las fórmulas:
$formulas:=New collection
$formulas.push(New collection("";"")) // primera colección
$formulas.push(New collection("";"")) // segunda colección
VP SET FORMULAS(VP Cell("ViewProArea";0;0);$formulas) // Asignar a celdas
VP Get Formulas
VP GET VALUESVP SET FORMULA
VP SET VALUES
VP SET FROZEN PANES ( vpAreaName : Text ; paneObj : Object { ; sheet : Integer } )
| Parámetros | Tipo | | Descripción |
|---|
| vpAreaName | Text | -> | Nombre de objeto formulario área 4D View Pro | | paneObj | Object | -> | Objeto que contiene la información de las columnas y líneas congeladas | | sheet | Integer | -> | Índice de la hoja (hoja actual si se omite) |
El comando VP SET FROZEN PANES define el estado congelado de las columnas y filas del paneObj para que se muestren siempre en el vpAreaName. . Frozen columns and rows are fixed in place and do not move when the rest of the document is scrolled. A solid line is displayed to indicate that columns and rows are frozen.
- Columnas a la izquierda o a la derecha: para las columnas a la izquierda de la hoja, la línea se muestra a la derecha de la última columna congelada. Para las columnas situadas a la derecha de la hoja, la línea se muestra a la izquierda de la primera columna congelada.
- Líneas en la parte superior o inferior: para las líneas en la parte superior de la hoja, la línea se muestra debajo de la última línea congelada. Para las líneas situadas en la parte inferior de la hoja, la línea se muestra sobre la primera línea congelada.
En vpAreaName, pase el nombre del área 4D View Pro. Si pasa un nombre que no existe, se devuelve un error.
Puede pasar un objeto que defina las columnas y líneas a congelar en el parámetro paneObj. Al definir el valor de una propiedad de columna o de línea en cero, se restablece (descongela) la propiedad. Si una propiedad está definida como menor que cero, el comando no hace nada. Puede pasar:
| Propiedad | Tipo | Descripción |
|---|
| columnCount | Integer | El número de columnas congeladas a la izquierda de la hoja | | trailingColumnCount | Integer | El número de columnas congeladas a la derecha de la hoja | | rowCount | Integer | El número de líneas congeladas en la parte superior de la hoja | | trailingRowCount | Integer | El número de líneas congeladas en la parte inferior de la hoja |
En el parámetro opcional sheet, puede designar una hoja específica donde se definirá el rango (la numeración comienza en 0). Si se omite, se utiliza por defecto la hoja de cálculo actual. Puede seleccionar explícitamente la hoja de cálculo actual con la siguiente constante:
Quiere congelar las tres primeras columnas de la izquierda, dos columnas de la derecha y la primera línea:
var $panes : Object
$panes:=New object
$panes.columnCount:=3
$panes.trailingColumnCount:=2
$panes.rowCount:=1
VP SET FROZEN PANES("ViewProArea";$panes)
VP Get frozen panes
VP SET NUM VALUE ( rangeObj : Object ; numberValue : Number { ; formatPattern : Text } )
| Parámetros | Tipo | | Descripción |
|---|
| rangeObj | Object | -> | Objeto rango | | numberValue | Number | -> | Valor del número a definir | | formatPattern | Text | -> | Formato del valor |
The VP SET NUM VALUE commandassigns a specified numeric value to a designated cell range.
En rangeObj, pase un rango de la(s) celda(s) (creadas, por ejemplo, con VP Cell o VP Column) cuyo valor desea especificar. Si rangeObj incluye varias celdas, el valor especificado se repetirá en cada una de ellas.
El parámetro numberValue especifica un valor numérico que se asignará al rangeObj.
El formatPattern opcional define un patrón para el parámetro numberValue.
//Definir el valor de la celda en 2
VP SET NUM VALUE(VP Cell("ViewProArea";3;2);2)
/Definir el valor de la celda y formatear en dólares
VP SET NUM VALUE(VP Cell("ViewProArea";3;2);12.356;"_($* #,##0.00_)")
Cell format
VP SET VALUE
VP SET PRINT INFO ( vpAreaName : Text ; printInfo : Object { ; sheet : Integer } )
| Parámetros | Tipo | | Descripción |
|---|
| vpAreaName | Text | -> | Nombre del área 4D View Pro | | printInfo | Object | -> | Objeto que contiene los atributos de impresión | | sheet | Integer | -> | Índice de la hoja (hoja actual si se omite) |
El comando VP SET PRINT INFO define los atributos que se utilizarán al imprimir vpAreaName.
Pase el nombre del área 4D View Pro en vpAreaName. Si pasa un nombre que no existe, se devuelve un error.
Puede pasar un objeto que contenga las definiciones para varios atributos de impresión en el parámetro printInfo. Para ver la lista completa de los atributos disponibles, consulte Atributos de impresión.
En el parámetro opcional sheet, puede designar una hoja específica a imprimir (la numeración comienza en 0). Si se omite, se utiliza por defecto la hoja de cálculo actual. Puede seleccionar explícitamente la hoja de cálculo actual con la siguiente constante:
El siguiente código imprimirá un área 4D View Pro en un documento PDF:
var $printInfo : Object
//declarar atributos de impresión objeto
$printInfo:=New object
//definir atributos de impresión
$printInfo.headerCenter:="&BS.H.I.E.L.D. &A Sales Per Region"
$printInfo.firstPageNumber:=1
$printInfo.footerRight:="page &P of &N"
$printInfo.orientation:=vk print page orientation landscape
$printInfo.centering:=vk print centering horizontal
$printInfo.columnStart:=0
$printInfo.columnEnd:=8
$printInfo.rowStart:=0
$printInfo.rowEnd:=24
$printInfo.showGridLine:=True
//Agregar logotipo corporativo
$printInfo.headerLeftImage:=logo.png
$printInfo.headerLeft:="&G"
$printInfo.showRowHeader:=vk print visibility hide
$printInfo.showColumnHeader:=vk print visibility hide
$printInfo.fitPagesWide:=1
$printInfo.fitPagesTall:=1
//imprimir documento PDF
VP SET PRINT INFO ("ViewProArea";$printInfo)
//exportar el PDF
VP EXPORT DOCUMENT("ViewProArea";"Sales2018.pdf";New object("formula";Formula(ALERT("PDF ready!"))))
El PDF:
4D View Pro print attributes
VP Convert to picture
VP Get print info
VP PRINT
VP SET ROW ATTRIBUTES ( rangeObj : Object ; propertyObj : Object )
| Parámetros | Tipo | | Descripción |
|---|
| rangeObj | Object | -> | Rango de líneas | | propertyObj | Object | -> | Objeto que contiene las propiedades de las líneas |
El comando VP SET ROW ATTRIBUTES aplica los atributos definidos en el propertyObj a las filas del rangeObj.
En rangeObj, pase un objeto que contenga un rango. Si el rango contiene tanto columnas como líneas, los atributos se aplican sólo a las líneas.
El parámetro propertyObj permite especificar los atributos que se aplicarán a las líneas del rangeObj. Estos atributos son:
| Propiedad | Tipo | Descripción |
|---|
| height | number | Altura de la línea expresada en píxeles | | pageBreak | boolean | True para insertar un salto de página antes de la primera línea del rango, si no, false | | visible | boolean | True si la fila es visible, si no, false | | redimensionable | boolean | True si la línea puede redimensionarse, si no, false | | header | text | Texto del encabezado de la línea |
Quiere cambiar el tamaño de la segunda línea y definir el encabezado:
var $row; $properties : Object
$row:=VP Row("ViewProArea";1)
$properties:=New object("height";75;"header";"June")
VP SET ROW ATTRIBUTES($row;$properties)
VP Get row attributes
VP get column attributes
VP SET ROW ATTRIBUTES
VP SET ROW COUNT ( vpAreaName : Text ; rowCount : Integer { ; sheet : Integer } )
| Parámetros | Tipo | | Descripción |
|---|
| vpAreaName | Text | -> | Nombre de objeto formulario área 4D View Pro | | rowCount | Integer | -> | Número de líneas | | sheet | Integer | -> | Índice de la hoja (hoja actual si se omite) |
El comando VP SET ROW COUNT define el número total de filas en vpAreaName.
En vpAreaName, pase el nombre del área 4D View Pro. Si pasa un nombre que no existe, se devuelve un error.
Pase el número total de líneas en el parámetro rowCount. rowCount debe ser mayor que 0.
En el parámetro opcional sheet, puede designar una hoja de cálculo específica en la que se aplicará rowCount (el conteo comienza en 0). Si se omite, se utiliza por defecto la hoja de cálculo actual. Puede seleccionar explícitamente la hoja de cálculo actual con la siguiente constante:
El siguiente código define cinco líneas en el área 4D View Pro:
VP SET ROW COUNT("ViewProArea";5)
VP Get column count
VP get row-count
VP SET COLUMN COUNT
VP SET SELECTION ( rangeObj : Object )
| Parámetros | Tipo | | Descripción |
|---|
| rangeObj | Object | -> | Objeto rango de celdas |
El comando VP SET SELECTION define las celdas especificadas como la selección y la primera celda como la celda activa.
En rangeObj, pase un objeto rango de celdas a designar como selección actual.
$currentSelection:=VP Combine ranges(VP Cells("myVPArea";3;2;1;6);VP Cells("myVPArea";5;7;1;7))
VP SET SELECTION($currentSelection)
VP Get active cell
VP Get selection
VP RESET SELECTION
VP SET ACTIVE CELL
VP ADD SELECTION
VP SHOW CELL
VP SET SHEET COUNT ( vpAreaName : Text ; number : Integer )
| Parámetros | Tipo | | Descripción |
|---|
| vpAreaName | Text | -> | Nombre de objeto formulario área 4D View Pro | | number | Integer | -> | Número de hojas |
El comando VP SET SHEET COUNT establece el número de hojas en vpAreaName.
En number, pase un número correspondiente a cuántas hojas contendrá el documento tras la ejecución del comando.
Atención: el comando borrará hojas si la cantidad anterior de hojas en su documento es superior al número pasado. Por ejemplo, si hay 5 hojas en su documento y define el conteo de hojas en 3, el comando borrará las hojas número 4 y 5.
El documento tiene actualmente una hoja:
Para definir el número de hojas en 3:
VP SET SHEET COUNT("ViewProArea";3)
VP Get sheet count
VP SET SHEET NAME ( vpAreaName : Text ; name : Text {; sheet: Integer} )
| Parámetros | Tipo | | Descripción |
|---|
| vpAreaName | Text | -> | Nombre de objeto formulario área 4D View Pro | | name | Text | -> | Nuevo nombre para la hoja | | sheet | Integer | -> | Índice de la hoja a renombrar |
El comando VP SET SHEET NAME cambia el nombre de una hoja del documento cargado en vpAreaName.
En vpAreaName, pase el nombre del área 4D View Pro.
En name, pase un nuevo nombre para la hoja.
En sheet, pase el índice de la hoja a renombrar.
La indexación comienza en 0.
Si no se pasa sheet, el comando renombra la hoja actual.
El nuevo nombre no puede contener los siguientes caracteres: *, :, [, ], ?,\,/
El comando no hace nada si:
- el nuevo nombre contiene caracteres prohibidos
- el nuevo valor del nombre está en blanco
- el nuevo nombre ya existe
- the passed sheet does not exist
Establezca el nombre de la tercera hoja como "Total first quarter":
VP SET SHEET NAME("ViewProArea";"Total first quarter";2)
VP SET SHEET OPTIONS ( vpAreaName : Text; sheetOptions : Object { ; sheet : Integer} )
| Parámetros | Tipo | | Descripción |
|---|
| vpAreaName | Text | -> | Nombre del área 4D View Pro | | sheetOptions | Object | -> | Opciones de la hoja a definir | | sheet | Integer | -> | Índice de la hoja (hoja actual si se omite) |
El comando VP SET SHEET OPTIONS permite definir varias opciones de hoja del área vpAreaName.
Pase el nombre del área de 4D View Pro en vpAreaName. Si pasa un nombre que no existe, se devuelve un error.
Pase un objeto que contenga las definiciones de las opciones a definir en el parámetro sheetOptions. Para ver la lista completa de las opciones disponibles, consulte el párrafo Opciones de hoja.
En el parámetro opcional sheet, puede designar una hoja específica (la numeración comienza en 0). Si se omite, se utiliza por defecto la hoja de cálculo actual. Puede seleccionar explícitamente la hoja de cálculo actual con la siguiente constante:
Quiere proteger todas las celdas excepto el rango C5:D10:
// Activar la protección en la hoja actual
var $options : Object
$options:=New object
$options.isProtected:=True
VP SET SHEET OPTIONS("ViewProArea";$options)
// marcar las celdas C5:D10 como "desbloqueadas"
VP SET CELL STYLE(VP Cells("ViewProArea";2;4;2;6);New object("locked";False))
Necesita proteger su documento mientras sus usuarios pueden redimensionar las líneas y columnas:
var $options : Object
$options:=New object
// Activar la protección
$options.isProtected:=True
$options.protectionOptions:=New object
// Permitir al usuario cambiar el tamaño de las líneas
$options.protectionOptions.allowResizeRows=True;
// Permitir al usuario cambiar el tamaño de las columnas
$options.protectionOptions.allowResizeColumns=True;
// Aplicar la protección en la hoja actual
VP SET SHEET OPTIONS("ViewProArea";$options)
Desea personalizar los colores de sus pestañas, líneas congeladas, líneas de cuadrícula, fondo de selección y borde de selección:
var $options : Object
$options:=New object
// Personalizar el color de la pestaña de la hoja 1
$options.sheetTabColor:="Black"
$options.gridline:=New object("color";"Purple")
$options.selectionBackColor:="rgb(255,128,0,0.4)"
$options.selectionBorderColor:="Yellow"
$options.frozenlineColor:="Gold"
VP SET SHEET OPTIONS("ViewProArea";$options;0)
// Personaliza el color de la pestaña de la joja 2
$options.sheetTabColor:="red"
VP SET SHEET OPTIONS("ViewProArea";$options;1)
// Personalizar el color de la pestaña de la hoja 3
$options.sheetTabColor:="blue"
VP SET SHEET OPTIONS("ViewProArea";$options;2)
Resultado:
Quiere ocultar las líneas de la cuadrícula, así como los encabezados de las líneas y columnas.
var $options : Object
$options:=New object
$options.gridline:=New object()
$options.gridline.showVerticalGridline:=False
$options.gridline.showHorizontalGridline:=False
$options.rowHeaderVisible:=False
$options.colHeaderVisible:=False
VP SET SHEET OPTIONS("ViewProArea";$options)
Resultado:
4D View Pro sheet options
VP Get sheet options
VP SET SHOW PRINT LINES ( vpAreaName : Text {; visible : Boolean}{; sheet : Integer} )
| Parámetros | Tipo | | Descripción |
|---|
| vpAreaName | Text | -> | Nombre de objeto formulario área 4D View Pro | | visible | Boolean | -> | Líneas de impresión mostradas si True (por defecto), ocultas si es False | | sheet | Integer | -> | Índice de la hoja (hoja actual si se omite) |
El comando VP SET SHOW PRINT LINES establece si se muestran las líneas de vista previa de impresión en una hoja de cálculo..
En vpAreaName, pase el nombre del área 4D View Pro.
En visible, pase True para mostrar las líneas de impresión, y False para ocultarlas. Por defecto se pasa True.
En sheet, pase el índice de la hoja objetivo. Si no se especifica ningún índice, el comando se aplica a la hoja actual.
La indexación comienza en 0.
La posición de las líneas de impresión de una hoja de cálculo varía según los saltos de página de dicha hoja.
El siguiente código muestra las líneas de impresión en la segunda hoja de un documento:
VP SET SHOW PRINT LINES("ViewProArea";True;1)
Con un salto de página:
4D Get show print lines
Historia
| Lanzamiento | Modificaciones |
|---|
| 19 R7 | Añadidos |
VP SET TABLE COLUMN ATTRIBUTES ( vpAreaName : Text ; tableName : Text ; column : Integer ; attributes : Object {; sheet : Integer } )
| Parámetros | Tipo | | Descripción |
|---|
| vpAreaName | Text | -> | Nombre de objeto formulario área 4D View Pro | | tableName | Text | -> | Table name | | column | Integer | -> | Índice de la columna en la tabla | | attributes | Object | -> | Atributo(s) a aplicar a column | | sheet | Integer | -> | Índice de la hoja (hoja actual si se omite) |
El comando VP SET TABLE COLUMN ATTRIBUTES aplica los atributos definidos a la columna en la tableName.
En vpAreaName, pase el nombre del área 4D View Pro.
En el parámetro attributes, pase un objeto que contenga las propiedades a definir:
| Propiedad | Tipo | Descripción |
|---|
| dataField | text | Nombre de la propiedad de la columna de la tabla en el contexto de datos. | | name | text | Nombre de la columna de la tabla. Debe ser único en la tabla. Si este nombre ya es utilizado por otra columna, no se aplica y se utiliza automáticamente un nombre por defecto. | | formula | text | Define la fórmula para cada celda de la columna. See Structured Reference Formulas in the SpreadJS documentation | | footerText | text | Valor del pie de columna. | | footerFormula | text | Fórmula del pie de columna. | | filterButtonVisible | boolean | Define si se muestra el botón de filtro de la columna de la tabla (por defecto es True cuando se crea la tabla). |
En sheet, pase el índice de la hoja objetivo. Si no se especifica ningún índice o si pasa -1, el comando se aplica a la hoja actual.
La indexación comienza en 0.
Si no se encuentra tableName o si column es mayor que el número de columnas, el comando no hace nada.
Usted crea una tabla con un contexto de datos:
var $context;$options : Object
$context:=New object()
$context.col:=New collection()
$context.col.push(New object("name"; "Smith"; "firstname"; "John"; "salary"; 10000))
$context.col.push(New object("name"; "Wesson"; "firstname"; "Jim"; "salary"; 50000))
$context.col.push(New object("name"; "Gross"; "firstname"; "Maria"; "salary"; 10500))
VP SET DATA CONTEXT("ViewProArea"; $context)
//Define las columnas para la tabla
$options:=New object()
$options.tableColumns:=New collection()
$options.tableColumns.push(New object("name"; "Last Name"; "dataField"; "name"))
$options.tableColumns.push(New object("name"; "Salary"; "dataField"; "salary"))
VP CREATE TABLE(VP Cells("ViewProArea"; 1; 1; 2; 3); "PeopleTable"; "col"; $options)
A continuación, desea insertar una columna con datos del contexto de datos y ocultar algunos botones de filtro:
//insertar una columna
VP INSERT TABLE COLUMNS("ViewProArea"; "PeopleTable"; 1; 1)
var $param : Object
$param:=New object()
// Vincular la columna al campo firstname del datacontext
$param.dataField:="firstname"
// Cambiar el nombre por defecto de la columna a "First name"
// y ocultar el botón filtro
$param.name:="First Name"
$param.filterButtonVisible:=False
VP SET TABLE COLUMN ATTRIBUTES("ViewProArea"; "PeopleTable"; 1; $param)
// Ocultar el botón de filtro de la primera columna
VP SET TABLE COLUMN ATTRIBUTES("ViewProArea"; "PeopleTable"; 0; \
New object("filterButtonVisible"; False))
VP CREATE TABLE
VP Find table
VP Get table column attributes
VP RESIZE TABLE
Historia
| Lanzamiento | Modificaciones |
|---|
| 19 R8 | Añadidos |
VP SET TABLE THEME ( vpAreaName : Text ; tableName : Text ; options : cs.ViewPro.TableTheme )
| Parámetros | Tipo | | Descripción |
|---|
| vpAreaName | Text | -> | Nombre de objeto formulario área 4D View Pro | | tableName | Text | -> | Table name | | options | cs.ViewPro.TableTheme | -> | Propiedades del tema de la tabla a modificar |
El comando VP SET TABLE THEME modifica el tema actual de tableName.
En vpAreaName, pase el nombre del área 4D View Pro y en tableName, el nombre de la tabla a modificar.
En el parámetro options, pase un objeto de la clase cs.ViewPro.TableTheme que contenga las propiedades del tema a modificar.
Desea definir un tema predefinido en una tabla:
var $param : cs.ViewPro.TableTheme
$param:=cs.ViewPro.TableTheme.new()
$param.theme:="medium2"
VP SET TABLE THEME("ViewProArea"; "myTable"; $param)
Quiere tener esta representación de columna alternativa:
var $param : cs.ViewPro.TableTheme
$param:=cs.ViewPro.TableTheme.new()
// Activar el renderizado de columnas band
$param.bandColumns:=True
$param.bandRows:=False
// Crear el objeto tema con estilos de encabezado y columna
$param.theme:=cs.ViewPro.TableThemeOptions.new()
var $styleHeader; $styleColumn; $styleColumn2 : cs.ViewPro.TableStyle
$styleHeader:=cs.ViewPro.TableStyle.new()
$styleHeader.backColor:="Gold"
$styleHeader.foreColor:="#03045E"
$param.theme.headerRowStyle:=$styleHeader
$styleColumn1:=cs.ViewPro.TableStyle.new()
$styleColumn1.backColor:="SkyBlue"
$styleColumn1.foreColor:="#03045E"
$param.theme.firstColumnStripStyle:=$styleColumn1
$styleColumn2:=cs.ViewPro.TableStyle.new()
$styleColumn2.backColor:="LightCyan"
$styleColumn2.foreColor:="#03045E"
$param.theme.secondColumnStripStyle:=$styleColumn2
VP SET TABLE THEME("ViewProArea"; "myTable"; $param)
VP CREATE TABLE
VP Get table theme
VP SET TEXT VALUE
VP SET TEXT VALUE ( rangeObj : Object ; textValue : Text { ; formatPattern : Text } )
| Parámetros | Tipo | | Descripción |
|---|
| rangeObj | Object | -> | Objeto rango | | textValue | Text | -> | Valor texto a definir | | formatPattern | Text | -> | Formato del valor |
El comando VP SET TEXT VALUE asigna un valor de texto especificado a un rango de celdas designado.
En rangeObj, pase un rango de la(s) celda(s) (creadas, por ejemplo, con VP Cell o VP Column) cuyo valor desea especificar. Si rangeObj incluye varias celdas, el valor especificado se repetirá en cada una de ellas.
El parámetro textValue indica un valor texto que se asignará a rangeObj.
El formatPattern opcional define un patrón para el parámetro textValue.
VP SET TEXT VALUE(VP Cell("ViewProArea";3;2);"Test 4D View Pro")
Cell Format
VP SET VALUE
VP SET TIME VALUE ( rangeObj : Object ; timeValue : Time { ; formatPattern : Text } )
| Parámetros | Tipo | | Descripción |
|---|
| rangeObj | Object | -> | Objeto rango | | timeValue | Time | -> | Valor hora a definir | | formatPattern | Text | -> | Formato del valor |
El comando VP SET TIME VALUE asigna un valor de tiempo especificado a un rango de celdas designado.
En rangeObj, pase un rango de la(s) celda(s) (creadas, por ejemplo, con VP Cell o VP Column) cuyo valor desea especificar. Si rangeObj incluye varias celdas, el valor especificado se repetirá en cada una de ellas.
El parámetro timeValue indica una hora expresada en segundos que se asignará al rangeObj.
El formatPattern opcional define un patrón para el parámetro timeValue.
//Definir el valor para la hora actual
VP SET TIME VALUE(VP Cell("ViewProArea";5;2);Current time)
//Definir el valor para una hora específica con un formato designado
VP SET TIME VALUE(VP Cell("ViewProArea";5;2);?12:15:06?;vk pattern long time)
Cell Format
VP SET DATE TIME VALUE
VP SET VALUE
VP SET VALUE ( rangeObj : Object ; valueObj : Object )
| Parámetros | Tipo | | Descripción |
|---|
| rangeObj | Object | -> | Objeto rango | | valueObj | Object | -> | Valores de la celda y opciones de formato |
El comando VP SET VALUE asigna un valor especificado a un rango de celdas designado.
El comando permite utilizar un código genérico para definir y formatear los tipos de valores en rangeObj, mientras que otros comandos, como VP SET TEXT VALUE y VP SET NUM VALUE, reducen los valores a tipos específicos.
En rangeObj, pase un rango de la(s) celda(s) (creadas, por ejemplo, con VP Cell o VP Column) cuyo valor desea especificar. Si rangeObj incluye varias celdas, el valor especificado se repetirá en cada una de ellas.
El parámetro valueObj es un objeto que incluye propiedades para el valor y el formato a asignar a rangeObj. Puede contener las siguientes propiedades:
| Propiedad | Tipo | Descripción |
|---|
| value | Integer, Real, Boolean, Text, Date, Null | Valor a asignar a rangeObj (excepto- hora). Pase null para borrar el contenido de la celda. | | time | Real | Valor hora (en segundos) a asignar a rangeObj | | format | Text | Patrón de propiedad valor/tiempo. Para obtener información sobre patrones y caracteres de formato, consulte el párrafo Formato de celda. |
//Set the cell value as False
VP SET VALUE(VP Cell("ViewProArea";3;2);New object("value";False))
//Set the cell value as 2
VP SET VALUE(VP Cell("ViewProArea";3;2);New object("value";2))
//Set the cell value as $125,571.35
VP SET VALUE(VP Cell("ViewProArea";3;2);New object("value";125571.35;"format";"_($* #,##0.00_)"))
//Set the cell value as Hello World!
VP SET VALUE(VP Cell("ViewProArea";3;2);New object("value";"Hello World!"))
//Set the cell value as current date
VP SET VALUE(VP Cell("ViewProArea";4;2);New object("value";Current date))
//Set the cell value as current hour
VP SET VALUE(VP Cell("ViewProArea";5;2);New object("time";Current hour))
//Set the cell value as specific date and time
VP SET VALUE(VP Cell("ViewProArea";3;9);New object("value";!2024-12-18!);"time";?14:30:10?;"format";vk pattern full date time))
//Erase cell content
VP SET VALUE(VP Cell("ViewProArea";3;9);New object("value";Null))
Cell Format
VP Get values
VP SET VALUE
VP SET BOOLEAN VALUE
VP SET DATE TIME VALUE
VP SET FIELD
VP SET FORMULA
VP SET NUM VALUE
VP SET TEXT VALUE
VP SET TIME VALUE
VP SET VALUES ( rangeObj : Object ; valuesCol : Collection )
| Parámetros | Tipo | | Descripción |
|---|
| rangeObj | Object | -> | Objeto rango | | valuesCol | Collection | -> | Colección de valores |
El comando VP SET VALUES asigna una colección de valores comenzando en el rango de celdas especificado.
En rangeObj, pase un rango de celda (creada con VP Cell) cuyo valor desea especificar. La celda definida en rangeObj se utiliza para determinar el punto de partida.
- Si rangeObj no es un rango de celdas, sólo se utilizará la primera celda del rango.
- Si rangeObj incluye varios rangos, sólo se utilizará la primera celda del primer rango.
El parámetro valuesCol es bidimensional:
- La colección de primer nivel contiene subcolecciones de valores. Cada subcolección define una línea. Pasa una colección vacía para saltar una línea.
- Cada subcolección define los valores de las celdas para la línea. Los valores pueden ser enteros, reales, booleanos, texto, fecha, null u objeto. Si el valor es un objeto, puede tener las siguientes propiedades:
| Propiedad | Tipo | Descripción |
|---|
| value | Integer, Real, Boolean, Text, Date, Null | Valor de la celda (excepto - time) | | time | Real | Valor hora (en segundos) |
$param:=New collection
$param.push(New collection(1;2;3;False)) //primera línea, 4 valores
$param.push(New collection) //segunda línea, sin tocar
$param.push(New collection(4;5;Null;"hello";"world")) // tercera línea, 5 valores
$param.push(New collection(6;7;8;9)) //cuarta línea, 4 valores
$param.push(New collection(Null;New object("value";Current date;"time";42))) //quinta línea, 1 valor
VP SET VALUES(VP Cell("ViewProArea";2;1);$param)
VP Get formulas
VP Get value
VP Get Values
VP SET FORMULAS
VP SET VALUE
VP SET WORKBOOK OPTIONS ( vpAreaName : Text ; optionObj : Object)
| Parámetros | Tipo | | Descripción |
|---|
| vpAreaName | Text | -> | Nombre de objeto formulario área 4D View Pro | | optionObj | Object | -> | Objeto que contiene las opciones del libro de trabajo a definir |
VP SET WORKBOOK OPTIONS
define las opciones del libro de trabajo en vpAreaName.
En vpAreaName, pase el nombre del área 4D View Pro.
En optionObj, pase las opciones del libro de trabajo a aplicar a vpAreaName.
Si optionObj está vacío, el comando no hace nada.
Las opciones modificadas del libro de trabajo se guardan con el documento.
En la siguiente tabla se listan las opciones de libros de trabajo disponibles:
| Propiedad | Tipo | Descripción |
|---|
| allowUserDragMerge | boolean | Se permite la operación de fusión por arrastre (seleccionar celdas y arrastrar la selección para fusionar celdas) | | allowAutoCreateHyperlink | boolean | Permite la creación automática de hipervínculos en la hoja de cálculo. | | allowContextMenu | boolean | Se puede abrir el menú contextual integrado. | | allowCopyPasteExcelStyle | boolean | Los estilos de una hoja de cálculo pueden copiarse y pegarse en Excel, y viceversa. | | allowDynamicArray | boolean | Permite arrays dinámicos en hojas de cálculo | | allowExtendPasteRange | boolean | Amplía el rango pegado si éste no es suficiente para los datos pegados | | allowSheetReorder | boolean | Se permite reordenar la hoja | | allowUndo | boolean | Deshacer ediciones está permitido. | | allowUserDeselect | boolean | Se permite desmarcar celdas específicas de una selección. | | allowUserDragDrop | boolean | Se permite arrastrar y soltar los datos del rango | | allowUserDragFill | boolean | Se permite el relleno por arrastre | | allowUserEditFormula | boolean | Las fórmulas pueden introducirse en las celdas | | allowUserResize | boolean | Columnas y filas redimensionables | | allowUserZoom | boolean | Se permite hacer zoom (ctrl + rueda del ratón) | | autoFitType | number | El contenido se formatea para que se ajuste en las celdas, o en las celdas y los encabezados. Valores disponibles: | Constante | Valor | Descripción |
|---|
| vk auto fit type cell | 0 | El contenido se ajusta automáticamente a las celdas | | vk auto fit type cell with header | 1 | El contenido se ajusta automáticamente a las celdas y encabezados |
| | backColor | string | Una cadena de color utilizada para representar el color de fondo del área, como "red", "#FFFF00", "rgb(255,0,0)", "Acento 5". El color de fondo inicial se oculta cuando se define una backgroundImage. | | backgroundImage | string / picture / file | Imagen de fondo para el área. | | backgroundImageLayout | number | Cómo se muestra la imagen de fondo. Valores disponibles: | Constante | Valor | Descripción |
|---|
| vk image layout center | 1 | En el centro del área. | | vk image layout none | 3 | En la esquina superior izquierda del área con su tamaño original. | | vk image layout stretch | 0 | Llena el área. | | vk show resize tip none | 0 | No se muestra ningún consejo de redimensionamiento. |
| | calcOnDemand | boolean | Las fórmulas se calculan sólo cuando se piden. | | columnResizeMode | number | Redimensiona modo para columnas. Valores disponibles: | Constante | Valor | Descripción |
|---|
| vk resize mode normal | 0 | Utiliza el modo de redimensionamiento normal (es decir, las columnas restantes se ven afectadas) | | vk resize mode split | 1 | Utiliza el modo dividido (es decir, las columnas restantes no se ven afectadas) |
| | copyPasteHeaderOptions | number | Encabezados para incluir cuando se copian o pegan datos. Encabezados para incluir cuando se copian o pegan datos.Valores disponibles:Valores disponibles:| Constante | Valor | Descripción |
|---|
| vk copy paste header options all headers | 3 | Incluye los encabezados seleccionados cuando se copian los datos; sobrescribe los encabezados seleccionados cuando se pegan los datos. |
| Constante | Valor | Descripción |
|---|
| vk copy paste header options all headers | 3 | Incluye los encabezados seleccionados cuando se copian los datos; sobrescribe los encabezados seleccionados cuando se pegan los datos. | | vk copy paste header options column headers | 2 | Incluye los encabezados de columnas seleccionadas cuando se copian los datos; sobrescribe los encabezados de columna seleccionados cuando se pegan los datos. | | vk copy paste header options no headers | 0 | Los encabezados de columnas y de líneas no se incluyen cuando se copian los datos; los encabezados de columnas o de líneas selecciondos no sobreescriben los encabezados de columnas o filas cuando se pegan los datos. |
| | customList | collection | La lista para que los usuarios personalicen el relleno de arrastre, dar prioridad a que coincida con esta lista en cada relleno. Cada elemento de colección es una colección de cadenas. See on GrapeCity's website. | | cutCopyIndicatorBorderColor | string | Color del borde del indicador que aparece cuando el usuario corta o copia la selección. | | cutCopyIndicatorVisible | boolean | Muestra un indicador al copiar o cortar el elemento seleccionado. | | defaultDragFillType | number | El tipo de relleno de arrastre por defecto. Valores disponibles : Valores disponibles : | Constante | Valor | Descripción |
|---|
| vk auto fill type auto | 5 | Rellena automáticamente las celdas. | | vk auto fill type clear values | 4 | Borra los valores de las celdas. |
| Constante | Valor | Descripción |
|---|
| vk auto fill type auto | 5 | Rellena automáticamente las celdas. | | vk auto fill type clear values | 4 | Borra los valores de las celdas. | | vk auto fill type copycells | 0 | Llena las celdas con todos los objetos de datos, incluyendo valores, formato y fórmulas. | | vk auto fill type fill without formatting | 3 | Rellena las celdas con valores y no con formato. |
| | enableAccessibility | boolean | El soporte de accesibilidad está activado en la hoja de cálculo. | | enableFormulaTextbox | boolean | Se activa la caja de texto de la fórmula. | | grayAreaBackColor | string | Una cadena color utilizada para representar el color de fondo del área gris, como "red", "#FFFF00", "rgb(255,0,0)", "Accent 5", etc. | | highlightInvalidData | boolean | Los datos inválidos son resaltados. | | iterativeCalculation | boolean | Activa el cálculo iterativo. See on Grapecity's website. | | iterativeCalculationMaximumChange | numeric | Cantidad máxima de cambio entre dos valores de cálculo. | | iterativeCalculationMaximumIterations | numeric | Número de veces que la fórmula debe recalcular. | | newTabVisible | boolean | Mostrar una pestaña especial para permitir a los usuarios insertar nuevas hojas. | | numbersFitMode | number | Cambia el modo de visualización cuando el ancho de los datos de fecha/número es mayor que el ancho de la columna. Valores disponibles: | Constante | Valor | Descripción |
|---|
| vk numbers fit mode mask | 0 | Sustituye el contenido de los datos por "###" y muestra la punta | | vk numbers fit mode overflow | 1 | Muestra el contenido de los datos como una cadena. Si la siguiente celda está vacía, se desborda el contenido. |
| | pasteSkipInvisibleRange | boolean | Paste or skip pasting data in invisible ranges: - False (default): paste data
- True: Skip pasting in invisible ranges
See Grapecity's docs for more information on invisible ranges. | | referenceStyle | number | Estilo para referencias de celdas y rangos en fórmulas de celdas. Valores disponibles: | Constante | Valor | Descripción |
|---|
| vk reference style A1 | 0 | Utiliza el estilo A1. | | vk estilo de referencia R1C1 | 1 | Utilizar el estilo R1C1 |
| | resizeZeroIndicator | number | Política de dibujo cuando las líneas o columnas se redimensionan a 0. Política de dibujo cuando las líneas o columnas se redimensionan a 0.Valores disponibles:Valores disponibles:| Constante | Valor | Descripción |
|---|
| vk resize zero indicator default | 0 | Utiliza la política de dibujo actual cuando la fila o columna se redimensiona a cero. |
| Constante | Valor | Descripción |
|---|
| vk resize zero indicator default | 0 | Utiliza la política de dibujo actual cuando la fila o columna se redimensiona a cero. |
| | rowResizeMode | number | La forma en que se redimensionan las líneas. Los valores disponibles son los mismos qe columnResizeMode | | scrollbarAppearance | number | Apariencia de la barra de desplazamiento. Apariencia de la barra de desplazamiento.Valores disponibles: | Constante | Valor | Descripción |
|---|
| vk scrollbar appearance mobile | 1 | Aspecto de la barra de desplazamiento móvil. |
| | scrollbarMaxAlign | boolean | La barra de desplazamiento se alinea con la última línea y columna de la hoja activa. | | scrollbarShowMax | boolean | Las barras de desplazamiento mostradas se basan en el número total de columnas y líneas de la hoja. | | scrollByPixel | boolean | Activar desplazamiento de precisión por píxel. | | scrollIgnoreHidden | boolean | La barra de desplazamiento ignora líneas o columnas ocultas. | | scrollPixel | integer | Decide el desplazamiento por ese número de píxeles cuando scrollByPixel es true. Decide el desplazamiento por ese número de píxeles cuando scrollByPixel es true. Por ejemplo: delta de desplazamiento es 3, scrollPixel es 5, los píxeles finales de desplazamiento son 15. | | showDragDropTip | boolean | Mostrar la punta de arrastrar y soltar. | | showDragFillSmartTag | boolean | Mostrar el diálogo de arrastrar y rellenar. | | showDragFillTip | boolean | Mostrar la punta de arrastrar y soltar. | | showHorizontalScrollbar | boolean | Mostrar la barra de desplazamiento horizontal. | | showResizeTip | number | Cómo mostrar el tip de redimensionamiento. Cómo se muestra la imagen de fondo.Valores disponibles: | Constante | Valor | Descripción |
|---|
| vk image layout center | 1 | En el centro del área. | | vk image layout none | 3 | En la esquina superior izquierda del área con su tamaño original. | | vk image layout stretch | 0 | Llena el área. |
| | showScrollTip | number | Cómo mostrar el tip de desplazamiento. Cómo mostrar el tip de desplazamiento.Valores disponibles: Valores disponibles: | Constante | Valor | Descripción |
|---|
| vk show scroll tip both | 3 | Se muestran los consejos de desplazamiento horizontal y vertical. |
| Constante | Valor | Descripción |
|---|
| vk show scroll tip both | 3 | Se muestran los consejos de desplazamiento horizontal y vertical. | | vk show scroll tip none | 0 | No scroll tip is displayed. | | vk show scroll tip none | No se muestra ninguna propina. |
| | showVerticalScrollbar | boolean | Mostrar la barra de desplazamiento vertical. | | tabEditable | boolean | La pestaña de la hoja se puede editar. | | tabNavigationVisible | boolean | Mostrar la navegación por pestañas. | | tabStripPosition | number | Posición de la barra de pestañas. Posición de la barra de pestañas.Valores disponibles:Valores disponibles:| Constante | Valor | Descripción |
|---|
| vk tab strip position bottom | 0 | La posición de la barra de pestañas es relativa a la parte inferior del libro. |
| Constante | Valor | Descripción |
|---|
| vk tab strip position bottom | 0 | La posición de la barra de pestañas es relativa a la parte inferior del libro. | | vk tab strip position left | 2 | La posición de la barra de tabulación es relativa a la parte izquierda del libro de trabajo. | | vk tab strip position right | 3 | La posición de la barra de tabulación es relativa a la parte derecha del libro de trabajo. |
| | tabStripRatio | number | Valor porcentual (0,x) que especifica qué parte del espacio horizontal se asignará al tabulador. El resto del área horizontal (1 - 0.x) se asignará a la barra de desplazamiento horizontal. | | tabStripVisible | boolean | Mostrar la barra de pestañas de la hoja. | | tabStripWidth | number | Ancho de la etiqueta cuando la posición es izquierda o derecha. Por defecto y el mínimo es 80. | | useTouchLayout | boolean | Si se va a utilizar el diseño táctil para presentar el componente Spread. |
Para definir la opción allowExtendpasteRange en "ViewProArea":
var $workbookOptions : Object
$workbookOptions:= New Object
$workbookOptions.allowExtendPasteRange:=True
VP SET WORKBOOK OPTIONS("ViewProArea";$workbookOptions)
VP Get workbook options
VP SHOW CELL ( rangeObj : Object { ; vPos : Integer; hPos : Integer } )
| Parámetros | Tipo | | Descripción |
|---|
| rangeObj | Object | -> | Objeto rango | | vPos | Integer | -> | Posición vertical de la vista de la celda o de la línea | | hPos | Integer | -> | Posición horizontal de la vista de la celda o de la línea |
El comando VP SHOW CELL reposiciona vertical y horizontalmente la vista del rangeObj.
En rangeObj, pase un rango de celdas como objeto para designar las celdas a visualizar. La vista del rangeObj se posicionará vertical u horizontalmente (es decir, donde aparezca rangeObj) en función de los parámetros vPos y hPos. El parámetro vPos define la posición vertical deseada para mostrar el rrangeObj y el parámetro hPos define la posición horizontal deseada para mostrar el rangeObj.
Los siguientes selectores están disponibles:
| Selector | Descripción | Disponible con vPos | Disponible con hPos |
|---|
vk position bottom | Alineación vertical a la parte inferior de la celda o de la línea. | X | | vk position center | Alineación al centro. El alineamiento será a la celda, fila, o límite de columna según la posición indicada en la vista:Posición de la vista vertical - celda o filaPosición horizontal de la vista - celda o columna | X | X | vk position left | Alineación horizontal a la izquierda de la celda o columna | | X | vk position nearest | Alineación al límite más cercano (arriba, abajo, izquierda, derecha, centro). La alineación será a la celda, fila o límite de columna según la posición indicada en la vista:Posición de la vista vertical (arriba, centro, abajo) - celda o fila Posición de la vista horizontal (izquierda, centro, derecha) - celda o columna | X | X | vk position right | Alineación horizontal a la derecha de la celda o de la columna | | X | vk position top | Alineación vertical a la parte superior de la celda o de la línea | X | |
Este comando sólo es eficaz si es posible reposicionar la vista. Por ejemplo, si el rangeObj está en la celda A1 (la primera columna y la primera línea) de la hoja actual, reposicionar la vista no supondrá ninguna diferencia porque ya se han alcanzado los límites vertical y horizontal (es decir, no es posible desplazarse más arriba o más a la izquierda). Lo mismo ocurre si rangeObj está en la celda C3 y la vista se reposiciona al centro o abajo a la derecha. La vista permanece inalterada.
Quiere ver la celda en la columna AY, línea 51 en el centro del área 4D View Pro:
$displayCell:=VP Cell("myVPArea";50;50)
// Mover la vista para mostrar la celda
VP SHOW CELL($displayCell;vk position center;vk position center)
Resultado:
El mismo código con los selectores vertical y horizontal cambiados para mostrar la misma celda posicionada en la parte superior derecha del área 4D View Pro:
$displayCell:=VP Cell("myVPArea";50;50)
// Mover la vista para mostrar la celda
VP SHOW CELL($displayCell;vk position top;vk position right)
Resultado:
VP CELL
VP Get active cell
VP Get selection
VP RESET SELECTION
VP SET ACTIVE CELL
VP SET SELECTION
VP SUSPEND COMPUTING ( vpAreaName : Text )
| Parámetros | Tipo | | Descripción |
|---|
| vpAreaName | Text | -> | Nombre de objeto formulario área 4D View Pro |
El comando VP SUSPEND COMPUTING detiene el cálculo de todas las fórmulas en vpAreaName. Este comando es útil cuando se desea suspender los cálculos en esta área 4D View Pro para poder realizar manualmente modificaciones en las fórmulas sin encontrar errores antes de terminar de hacer los cambios.
El comando pausa los cálculos en 4D View Pro. Las fórmulas que ya han sido calculadas permanecen inalteradas, sin embargo cualquier fórmula añadida después de ejecutar el comando VP SUSPEND COMPUTING no es calculada.
En vpAreaName, pase el nombre del área 4D View Pro. Si pasa un nombre que no existe, se devuelve un error.
El servicio de cálculo de 4D View Pro mantiene un contador de acciones de suspensión/reanudación. Por lo tanto, cada ejecución del comando VP SUSPEND COMPUTING debe ser balanceada por una ejecución correspondiente del comando VP RESUME COMPUTING. Toda fórmula afectada por las modificaciones realizadas mientras los cálculos están suspendidos será recalculada cuando se ejecute el comando.
Ha añadido dos botones al formulario para que el usuario pueda suspender/reanudar los cálculos:
El código del botón Suspend Computing:
//pause calculations while users enter information
If(FORM Event.code=On Clicked)
VP SUSPEND COMPUTING("ViewProArea")
End if
If(FORM Event.code=On Clicked)
VP RESUME COMPUTING("ViewProArea")
End if
VP RECOMPUTE FORMULAS
VP RESUME COMPUTING
| 
