MAIL Convert to MIME
MAIL Convert to MIME( mail : Object { ; options : Object } ) : Text
| Parámetros | Tipo | Descripción | |
|---|---|---|---|
| Object | → | Objeto Email | |
| options | Object | → | Opciones de codificación y de charset del mail |
| Resultado | Text | ← | Objeto email convertido en MIME |
Historia
| Lanzamiento | Modificaciones |
|---|---|
| 17 R5 | Modificado |
| 17 R4 | Añadidos |
Descripción
El comando MAIL Convert to MIME convierte un objeto email en texto MIME. Este comando es llamado internamente por SMTP_transporter.send() para formatear el objeto email antes de enviarlo. Se puede utilizar para analizar el formato MIME del objeto.
En mail, pase el contenido y los detalles de la estructura del correo electrónico a convertir. Esto incluye información como las direcciones de correo electrónico (remitente y destinatario(s)), el propio mensaje y el tipo de visualización del mensaje.
4D sigue la especificación JMAP para formatear el objeto email.
En options, puede configurar la codificación y el charset del mail. Las siguientes propiedades están disponibles:
| Propiedad | Tipo | Descripción | |||||||||||||||
|---|---|---|---|---|---|---|---|---|---|---|---|---|---|---|---|---|---|
| headerCharset | Text | Charset y codificación utilizados para las siguientes partes del correo electrónico: asunto, nombres de archivos adjuntos y atributo(s) del nombre del correo electrónico. Valores posibles:
| |||||||||||||||
| bodyCharset | Text | Charset y codificación utilizados para el contenido html y el texto del cuerpo del correo electrónico. Valores posibles: los mismos que para headerCharset (ver arriba) |
Si se omite el parámetro options, se utiliza la configuración del modo de correo UTF8 para las partes encabezado y cuerpo.
Ejemplo
var $mail: Object
var $mime: Text
$mail:=New object
// Creation of a mail
$mail.from:="tsales@massmarket.com"
$mail.subject:="Terrific Sale! This week only!"
$mail.textBody:="Text format email"
$mail.htmlBody:="<html><body>HTML format email</body></html>"
$mail.to:=New collection
$mail.to.push(New object ("email";"noreply@4d.com"))
$mail.to.push(New object ("email";"test@4d.com"))
// transform the mail object in MIME
$mime:=MAIL Convert to MIME($mail)
// Contents of $mime:
// MIME-Version: 1.0
// Date: Thu, 11 Oct 2018 15:42:25 GMT
// Message-ID: <7CA5D25B2B5E0047A36F2E8CB30362E2>
// Sender: tsales@massmarket.com
// From: tsales@massmarket.com
// To: noreply@4d.com
// To: test@4d.com
// Content-Type: multipart/alternative; boundary="E0AE5773D5E95245BBBD80DD0687E218"
// Subject: Terrific Sale! This week only!
//
// --E0AE5773D5E95245BBBD80DD0687E218
// Content-Type: text/plain; charset="UTF-8"
// Content-Transfer-Encoding: quoted-printable
//
// Text format email
// --E0AE5773D5E95245BBBD80DD0687E218
// Content-Type: text/html; charset="UTF-8"
// Content-Transfer-Encoding: quoted-printable
//
// <html><body>HTML format email</body></html>
// --E0AE5773D5E95245BBBD80DD0687E218--
Propiedades
| Número de comando | 1604 |
| Hilo seguro | sí |