Objetos y colecciones compartidos

Los objetos compartidos y las colecciones compartidas son objetos y colecciones específicas cuyo contenido se comparte entre procesos. In contrast to interprocess variables, shared objects and shared collections have the advantage of being compatible with preemptive 4D processes: they can be passed by reference as parameters to commands such as New process or CALL WORKER.

Shared objects and shared collections are stored in standard Object and Collection type variables, but must be instantiated using specific commands:

• to create a shared object, use the New shared object command or call the new() function of a shared class,
• to create a shared collection, use the New shared collection command.

nota

Los objetos y colecciones compartidos pueden definirse como propiedades de objetos o colecciones estándar (no compartidos).

Para modificar un objeto/colección compartido, se debe llamar a la estructura Use...End use. La lectura de un valor de objeto/colección compartido no requiere Use...End use.

A unique, global catalog returned by the Storage command is always available throughout the application and its components, and can be used to store all shared objects and collections.

Utilización de objetos o colecciones compartidos

Una vez instanciado con los comandos Nuevo objeto compartido o Nueva colección compartida, las propiedades y elementos del objeto compartido/colección pueden ser modificados o leídos desde cualquier proceso de la aplicación, bajo ciertas condiciones.

Modificación

Las siguientes modificaciones pueden efectuarse en objetos y colecciones compartidos:

• añadir o eliminar propiedades de los objetos,
• añadir o editar valores (siempre que se soporten en objetos compartidos), incluyendo otros objetos compartidos o colecciones (lo que crea un grupo compartido, ver abajo).

All modification instructions in a shared object or collection require to be protected inside a Use...End use block, otherwise an error is generated.

 $s_obj:=New shared object("prop1";"alpha")
 Use($s_obj)
    $s_obj.prop1:="omega"
 End Use

Por comodidad, todas las funciones colección que modifican el objeto compartido o la colección insertan un bloque interno Use...End use para que no tenga que codificarlo usted mismo. Por ejemplo:

$col:=Nueva colección compartida()
$col.push("alpha") //.push() desencadena internamente el uso de Use/End, por lo que no es necesario que lo hagan ustedes mismos

Si necesita ejecutar varias modificaciones en la misma colección, puede proteger todas las modificaciones con un único Use...End use para que las modificaciones se realicen de forma atómica.

$col:=Storage.mySharedCollection
Use($col)
    $col[0]:="omega" //modifying an element requires to be performed inside Use/End use
    $col.push("alpha") //.push() internally triggers Use/End use, but we want to do both modifications atomically
End Use

Un objeto/una colección compartido(a) sólo puede modificarse por un proceso a la vez. Un objeto/una colección compartido(a) sólo puede modificarse por un proceso a la vez. . Intentar modificar un objeto/colección compartido sin al menos un Use...End use genera un error. Cuando un proceso llama a Use...End use en un objeto/colección compartido que ya está en uso por otro proceso, simplemente se pone en espera hasta que el End use lo desbloquee (no se genera ningún error). En consecuencia, las instrucciones dentro de las estructuras Use...End use deben ejecutarse rápidamente y desbloquear los elementos lo antes posible. Por lo tanto, se recomienda enfáticamente evitar modificar un objeto o colección compartido directamente desde la interfaz, por ejemplo, a través de una caja de diálogo.

La asignación de objetos/colecciones compartidos a propiedades o elementos de otros objetos/colecciones compartidos está permitida y crea grupos compartidos. Un grupo compartido se crea automáticamente cuando un objeto/colección compartido se define como valor de propiedad o elemento de otro objeto/colección compartido. Los grupos compartidos permiten anidar objetos y colecciones compartidos, pero imponen reglas adicionales:

• Al llamar a Use en un objeto/colección compartido que pertenece a un grupo se bloquean las propiedades/elementos de todos los objetos/colecciones del grupo y se incrementa su conteo de bloqueo. La llamada a End use disminuye el contador de bloqueo del grupo y cuando el contador está a 0, todos los objetos/colecciones compartidos vinculados se desbloquean.
• Un objeto/colección compartido sólo puede pertenecer a un grupo compartido. Se devuelve un error si se intenta asignar un objeto/colección compartido ya agrupado a un grupo diferente.
• Los objetos/colecciones compartidos agrupados no se pueden desagrupar. Una vez incluido en un grupo compartido, un objeto/colección compartido queda vinculado permanentemente a ese grupo durante toda la sesión. Incluso si todas las referencias de un objeto/colección se eliminan del objeto/colección padre, seguirán vinculadas.

Consulte el ejemplo 2 para ver una ilustración de las reglas de los grupos compartidos.

Nota: Los grupos compartidos se gestionan a través de una propiedad interna llamada locking identifier. Para obtener información detallada sobre este valor, consulte la Referencia del Lenguaje 4D.

Lectura

Se permite la lectura de propiedades o elementos de un objeto/colección compartida sin tener que llamar a la estructura Use...End use, incluso si el objeto/colección compartida está en uso por otro proceso.

Sin embargo, cuando varios valores son interdependientes y deben ser leídos simultáneamente, es necesario enmarcar el acceso de lectura con una estructura Use...End use por coherencia.

Duplication

Llamar a OB Copy con un objeto compartido (o con un objeto cuyas propiedades son objetos compartidos) es posible, pero en este caso se devuelve un objeto estándar (no compartido).

Storage

Storage es un objeto compartido único, disponible automáticamente en cada aplicación y máquina. This shared object is returned by the Storage command. Puede utilizar este objeto para hacer referencia a todos los objetos/colecciones compartidos definidos durante la sesión que desee que estén disponibles desde cualquier proceso preventivo o estándar.

Tenga en cuenta que, a diferencia de los objetos compartidos estándar, el objeto Storage no crea un grupo compartido cuando se añaden objetos/colecciones compartidos como sus propiedades. Esta excepción permite utilizar el objeto Storage sin bloquear todos los objetos o colecciones compartidos conectados.

For more information, refer to the Storage command description.

Use...End use

La sintaxis de la estructura Use...End use es:

 Use(Shared_object_or_Shared_collection)
    instrucción(es)
 End use

La estructura Use...End use define una secuencia de instrucciones que ejecutarán tareas sobre el parámetro Shared_object_or_Shared_collection bajo la protección de un semáforo interno. Shared_object_or_Shared_collection puede ser cualquier objeto o colección compartido válido.

Los objetos compartidos y las colecciones compartidas están diseñados para permitir la comunicación entre procesos, en particular, procesos 4D preferentes. Se pueden pasar por referencia como parámetros de un proceso a otro. Es obligatorio rodear las modificaciones en los objetos o colecciones compartidas con las palabras clave Use...End use para evitar el acceso concurrente entre procesos.

• Once the Use line is successfully executed, all Shared_object_or_Shared_collection properties/elements are locked for all other process in write access until the corresponding End use line is executed.
• The statement(s) sequence can execute any modification on the Shared_object_or_Shared_collection properties/elements without risk of concurrent access.
• If another shared object or collection is added as a property of the Shared_object_or_Shared_collection parameter, they become connected within the same shared group.
• If another process tries to access one of the Shared_object_or_Shared_collection properties or connected properties while a Use...End use sequence is being executed, it is automatically put on hold and waits until the current sequence is terminated.
• The End use line unlocks the Shared_object_or_Shared_collection properties and all objects of the same group.
• En el código 4D se pueden anidar varias estructuras Use...End use. Para modificar un objeto/colección compartido, se debe llamar a la estructura Use...End use.

nota

Las siguientes funciones activan automáticamente un Use/End use interno, haciendo innecesaria una llamada explícita a la estructura cuando se ejecuta la función:

• collection functions that modify shared collections
• funciones compartidas (definidas en clases compartidas).

Ejemplo 1

Se desea lanzar varios procesos que realicen una tarea de inventario en diferentes productos y que actualicen el mismo objeto compartido. El proceso principal instancia un objeto compartido vacío y luego, lanza los otros procesos, pasando el objeto compartido y los productos a contar como parámetros:

 ARRAY TEXT($_items;0)
 ... //llenar el array con los elementos a contar
 $nbItems:=Size of array($_items)
 var $inventory : Object
 $inventory:=New shared object
 Use($inventory)
    $inventory.nbItems:=$nbItems
 End use

  //Crear procesos
 For($i;1;$nbItems)
    $ps:=New process("HowMany";0;"HowMany_"+$_items{$i};$_items{$i};$inventory)
  //$inventory object sent by reference
 End for

En el método "HowMany", el inventario se realiza y el objeto compartido $inventory se actualiza lo antes posible:

    //HowMany
 #DECLARE ($what : Text ; $inventory : Object)

 $count:=CountMethod($what) //method to count products
 Use($inventory) //use shared object
    $inventory[$what]:=$count  //save the results for this item
 End use

Ejemplo 2

Los siguientes ejemplos ilustran las reglas específicas para el manejo de los grupos compartidos:

 $ob1:=New shared object
 $ob2:=New shared object
 Use($ob1)
    $ob1.a:=$ob2  //group 1 is created
 End use

 $ob3:=New shared object
 $ob4:=New shared object
 Use($ob3)
    $ob3.a:=$ob4  //group 2 is created
 End use

 Use($ob1) //use an object from group 1
    $ob1.b:=$ob4  //ERROR
  //$ob4 already belongs to another group
  //assignment is not allowed
 End use

 Use($ob3)
    $ob3.a:=Null //remove any reference to $ob4 from group 2
 End use

 Use($ob1) //use an object from group 1
    $ob1.b:=$ob4  //ERROR
  //$ob4 still belongs to group 2
  //assignment is not allowed
 End use