Versión: 20 R10 BETA

WP EXPORT DOCUMENT

WP EXPORT DOCUMENT ( wpDoc ; filePath {; format {; option}} )
WP EXPORT DOCUMENT ( wpDoc ; fileObj {; format {; option}} )

Parámetros	Tipo		Descripción
wpDoc	Object	→	Variable 4D Write Pro
filePath	Text	→	Ruta del archivo exportado
fileObj	4D.File	→	Objeto del archivo a exportar
format	Integer	→	Formato de salida del documento (por ejemplo, .docx, .pdf, etc.)
option	Object, Integer	→	Export options, which can vary depending on the format chosen.

Descripción

El comando WP EXPORT DOCUMENT exporta el objeto wpDoc 4D Write Pro a un documento en disco de acuerdo con el parámetro filePath o fileObj, así como cualquier parámetro opcional.

En wpDoc, pase el objeto 4D Write Pro que desea exportar.

Puede pasar un filePath o fileObj:

In filePath, pass the destination path and the name of the document to be exported. If you pass only the document name, it will be saved at the same level as the 4D structure file.
In fileObj parameter, pass a 4D.File object representing the file to be exported.

You can omit the format parameter, in which case you need to specify the extension in filePath. You can also pass a constant from the 4D Write Pro Constants theme in the format parameter. In this case, 4D adds the appropriate extension to the file name if needed. Se soportan los siguientes formatos:

Constante	Valor	Comentario
wk 4wp	4	4D Write Pro document is saved in a native archive format (zipped HTML and images saved in a separate folder). 4D specific tags are included and 4D expressions are not computed. This format is particularly suitable for saving and archiving 4D Write Pro documents on disk without any loss.
wk docx	7	Extensión .docx. El documento 4D Write Pro se guarda en formato Microsoft Word. Certified support for Microsoft Word 2010 and newer. The document parts exported are: Body / headers / footers / sectionsPage / print settings (margins, background color / image, borders, padding, paper size / orientation)Images - inline, anchored, and background image pattern (defined with wk background image)Compatible variables and expressions (page number, number of pages, date, time, metadata). Non-compatible variables and expressions will be evaluated and frozen before export.Links - BookmarksURLsNote that some 4D Write Pro settings may not be available or may behave differently in Microsoft Word.
wk mime html	1	4D Write Pro document is saved as standard MIME HTML with HTML documents and images embedded as MIME parts (encoded in base64). Expressions are computed and 4D specific tags and method links are removed. Only text boxes anchored to embedded view are exported (as divs). This format is particularly suitable for sending HTML emails with the command.
wk pdf	5	extensión .pdf. 4D Write Pro document is saved in PDF format, based on Page view mode. The following metadata is exported in a PDF document: Title Author Subject Content creator Notes: Expressions are automatically frozen when document is exported Links to methods are NOT exported
wk svg	8	4D Write Pro document page is saved in SVG format, based on Page view mode. Note: When exporting to SVG, you can only export one page at a time. Utilice el wk page index para especificar qué página exportar.
wk web page complete	2	Extensión .htm o .html. Document is saved as standard HTML and its resources are saved separately. 4D tags and links to 4D methods are removed and expressions are computed. Only text boxes anchored to embedded view are exported (as divs). Only text boxes anchored to embedded view are exported (as divs).

Notas:

"4D specific tags" means 4D XHTML with a 4D namespace and 4D CSS styles.
Para más información sobre el formato de documento 4D Write Pro, consulte el formato del documento .4wp.
To view a list of known differences or incompatibility when using the .docx format, see Importing and Exporting in .docx format.
For more information on exporting to SVG format, see Exporting to SVG format.

Parámetro option

Pase un objeto en option conteniendo los valores para definir las propiedades del documento exportado. Las siguientes propiedades están disponibles:

Constante	Valor	Comentario
wk CID host domain name	cidHostDomain	CID host domain name: host domain that will be added to generated CID URLs including an '@' as separator. Disponible sólo cuando se utiliza el formato `wk mime html`.
wk embedded pictures	embeddedPictures	Sólo para exportación SVG. Sets whether pictures are embedded in the exported .svg file when you call WP EXPORT DOCUMENT. Available values: true (default): Pictures are embedded in the exported .svg file false: Pictures are exported in a folder called "filename_images" at the level of the exported .svg file, "filename" being the name passed to the command for the file, without the extension. The pictures are not embedded, but referenced in the .svg file. Note: If the folder already exists, it is emptied before the file is exported. If there is no image on the exported page, the folder is deleted
wk factur x	facturX	Sólo para exportación en PDF. Valor: objeto que configura una exportación PDF "Factur-X (ZUGFeRD)" (ver wk factur x object).
wk files	Histórico	Sólo para exportación en PDF. Valor: colección de objetos, cada uno de los cuales describe un archivo que se integrará en el documento final (ver wk files collection). Esta funcionalidad sólo se admite en documentos PDF/A-3: cuando se utiliza el atributo `wk files`, se establece automáticamente la versión "PDF/A-3" (se ignora el atributo `wk pdfa version`). In case of a Factur-X PDF export (see below), the first object of the collection must contain the Factur-X xml file.
wk google fonts tag	googleFontsTag	Sólo para exportación SVG. Sets the import rule for google fonts in the exported SVG. Possible values: false (default): No google fonts import rule is added. true: Adds the @import rule to the exported file. Useful if you want to use fonts that are not available by default on Windows or macOS. Note: This property is set to false by default because when enabled, Google fonts override native fonts, and native fonts are generally better rendered in the browser.
wk HTML pretty print	htmlPrettyPrint	El código HTML está formateado para facilitar su lectura.
wk max picture DPI	maxPictureDPI	Se utiliza para reducir imágenes a la resolución preferida. For SVG images in Windows, used for rasterization. Default values: 300 (for wk optimized for = wk print) 192 (for wk optimized for = wk screen) Maximum possible value: 1440
wk optimized for	optimizedFor	Defines how an exported document is optimized based on its intended medium. Valores posibles: `wk print` (valor por defecto para `wk pdf` y `wk svg`) Las imágenes de mapa de bits pueden reducirse utilizando los PPP definidos por `wk max picture DPI` o 300 (valor por defecto) y pueden convertirse a PNG si el códec no es compatible con el tipo de exportación. Las imágenes vectoriales se convierten a PNG utilizando los PPP definidos por `wk max picture DPI` o 300 (sólo Windows). If a picture contains more than one format, the best format for printing is used (e.g., .tiff instead or .jpg) `wk screen` (default value for `wk web page complete` and `wk mime html`). Bitmap pictures may be downscaled using the DPI defined by `wk max picture DPI` or 192 (default value) and may be converted to JPEG (opaque images) or PNG (transparent images) if codec is not supported for the export type. Vectorial pictures are converted to PNG using the DPI defined by `wk max picture DPI` or 192 (Windows only). If a picture contains more than one format, the format for screen rendering is used. Nota: los documentos exportados en formato `wk docx` siempre se optimizan para la impresión wk (la opción wk optimized for se ignora).
wk page index	pageIndex	Sólo para exportación SVG. Índice de la página a exportar a formato svg (por defecto es 1). El índice de páginas comienza en 1 para la primera página del documento. Nota: el índice de páginas es independiente de la numeración de páginas.
wk pdfa version	pdfaVersion	Exporta PDF conforme a una versión PDF/A. For more information on PDF/A properties and versions, please refer to the PDF/A page on Wikipedia. Possible values: `wk pdfa2`: Exports to version "PDF/A-2" `wk pdfa3`: Exports to version "PDF/A-3" Note: On macOS, `wk pdfa2` may export to PDF/A-2 or PDF/A-3 or higher, depending on platform implementation. Además, `wk pdfa3` significa "exporta a al menos PDF/A-3". On Windows, the output PDF file will always be equal to the desired conformance.
wk recompute formulas	recomputeFormulas	Defines if formulas must be recomputed when exported. Valores posibles: true - Valor por defecto. All formulas are recomputed false - Do not recompute formulas
wk visible background and anchored elements	visibleBackground	Displays or exports background images/color, anchored images and text boxes (for display, visible effect in Page or Embedded view mode only). Valores posibles: True/False
wk visible empty images	visibleEmptyImages	Displays or exports a default black rectangle for images that cannot be loaded or computed (empty images or images in an unsupported format). Valores posibles: True/False. Default value: True If value is False, missing image elements will not be displayed at all even if they have borders, width, height, or background; this may impact the page layout for inline images.
wk visible footers	visibleFooters	Displays or exports the footers (for display, visible effect in Page view mode only). Valores posibles: True/False
wk visible headers	visibleHeaders	Displays or exports the headers (for display, visible effect in Page view mode only). Valores posibles: True/False
wk visible references	visibleReferences	Displays or exports all 4D expressions inserted in the document as references. Valores posibles: True/False
wk whitespace	whitespace	Sets the "white-space" css value for `wk mime html` and `wk web page complete` export formats. The white-space css style is applied to paragraphs. Possible values: "normal", "nowrap", "pre", "pre-wrap" (default), "pre-line", "break-spaces".

The following table indicates the option available per export format:

	wk 4wp	wk docx	wk mime html	wk pdf	wk web page complete	wk svg
wk CID host domain name	-	-		-	-	-
wk embedded pictures	-	-	-	-	-	(por defecto: true)
wk factur x	-	-	-		-	-
wk files	-	-	-		-	-
wk google fonts tag	-	-	-	-	-	(por defecto: false)
wk HTML pretty print	(por defecto: false)	-	(por defecto: False)	(por defecto: False)	(por defecto: False)	(por defecto: false)
wk max picture DPI	-	siempre 300		(por defecto: 300)	-	(por defecto: 300)
wk optimized for	-	always wk print	(por defecto: wk screen)	always wk print	-	(por defecto: wk print)
wk page index	-	-	-	-	-	(por defecto: 1)
wk pdfa version	-	-	-		-	-
wk recompute formulas	-	(por defecto: true)	(por defecto: true)	(por defecto: true)	-	(por defecto: true)
wk visible background and anchored elements	-	(por defecto: true)	siempre true	(por defecto: true)	-	(por defecto: true)
wk visible empty images	-	(por defecto: true)	(por defecto: true)	(por defecto: true)	-	(por defecto: true)
wk visible footers	-	siempre true	siempre false	(por defecto: true)	-	(por defecto: true)
wk visible headers	-	siempre true	siempre false	(por defecto: true)	-	(por defecto: true)
wk visible references	-	-	-	(por defecto: false)	-	(por defecto: false)
wk whitespace	-	-	(por defecto: "pre-wrap")	-	(por defecto: "pre-wrap")	-

Nota de compatibilidad: pasar un valor largo en longint es compatible por razones de compatibilidad, pero se recomienda usar un parámetro objeto.

colección wk files

The wk files property allows you to export a PDF with attachments. This property must contain a collection of objects describing the files to be embedded in the final document. Each object of the collection can contain the following properties:

Propiedad	Tipo	Description
name	Text	Nombre de archivo. Optional if the file property is used, in which case the name is inferred by default from the file name. Mandatory if the data property is used (except for the first file of a Factur-X export, in which case the name for the file is automatically "factur-x.xml", see below)
description	Text	Opcional. If omitted, default value for the first export file to Factur-X is "Factur-X/ZUGFeRD Invoice", otherwise empty.
mimeType	Text	Opcional. If omitted, default value can usually be guessed from file extension; otherwise, "application/octet-stream" is used. If passed, make sure to use an ISO mime type, otherwise the exported file could be invalid.
data	Texto o BLOB	Obligatorio si falta la propiedad file
file	Objeto 4D.File	Mandatory if data property is missing, ignored otherwise.
relationship	Text	Opcional. Si se omite, el valor por defecto es "Data". Possible values for Factur-X first file:for BASIC, EN 16931 or EXTENDED profiles: "Alternative", "Source" or "Data" ("Alternative" only for German invoice)for MINIMUM and BASIC WL profiles: "Data" only.for other profiles: "Alternative", "Source" or "Data" (with restrictions perhaps depending on country: see profile specification for more info about other profiles - for instance for RECHNUNG profile only "Alternative" is allowed)for other files (but Factur-X invoice xml file) : "Alternative", "Source", "Data", "Supplement" or "Unspecified"any other value generates an error.

Si el parámetro option también contiene una propiedad wk factur x, entonces el primer elemento de la colección wk files debe ser el fichero xml de la factura Factur-X (ZUGFeRD) (ver más abajo).

nota

Los archivos PDF adjuntos solo son compatibles con la versión PDF/A-3. When you pass the wk files property, the "PDF/A-3" version is automatically used.

Objeto wk factur x

The wk factur x property is an object that can contains up to two properties:

Propiedad	Tipo	Description
profile	Text	Opcional. If omitted, profile is determined from the provided xml file or text (which must use a standard profile). If passed, it can be a non-standard profile name (for using other profiles - for instance RECHNUNG). Note: Standard profile names are: MINIMUM, BASIC WL, BASIC, EN 16931 (aka COMFORT which is an alias), EXTENDED.
version	Text	Opcional. El valor por defecto es "1.0"

Acerca de los documentos PDF de Factur-X / ZUGFeRD

Factur-X / ZUGFeRD is a European standard for hybrid e-invoices (PDF for users and XML data for process automation). For more information, please read this blog post.

To trigger a "Factur-X" PDF export, pass both the wk factur x and wk files properties in the option parameter (see Example 5). En este caso:

se genera un Factur-X (ZUGFeRD) PDF,
the first element of the wk files collection is used as Factur-X xml file,
if the wk files property is missing or contains an empty collection, or if its first element is not a xml file, an error is generated.

nota

For a detailed example of Factur-X / ZUGFeRD export implementation, you can download this HDI 4D project.

Ejemplo 1

You want to export the contents of the myArea 4D Write Pro object in both HTML and PDF format:

  // export HTML
 var $option : Object
 $option:=New object

 $option[wk recompute formulas]:=False
 $option[wk HTML pretty print]:=False
 $option[wk optimized for]:=wk print
 $option[wk max picture DPI]:=600 //override default value for print (300 DPI)

 WP EXPORT DOCUMENT(myArea;$path;wk web page complete;$option)

  //export PDF
 var $option : Object
 $option:=New object

 $option[wk visible headers]:=True
 $option[wk visible footers]:=True
 $option[wk visible background]:=True
 $option[wk max picture DPI]:=96 //override default value for screen (192 DPI) to limit doc size
 $option[wk optimized for]:=wk screen
 $option[wk recompute formulas]:=True

 WP EXPORT DOCUMENT(myArea;$path;wk pdf;$option)

Ejemplo 2

You want to export the contents of the myArea 4D Write Pro object in .4wp format:

 var $path : Text

 Case of
    :(Form event code=On Clicked)

       $path:=Get 4D folder(Database folder)+"Export"+Folder separator
       $path:=Select document($path;".4wp";" title";File name entry)

       If($path#"")
          WP EXPORT DOCUMENT(myArea;document;wk 4wp)
       End if
 End case

Ejemplo 3

To export the second page of the document as SVG and export the pictures from the document:

 var $options : Object

 $options:=New object
 $options[wk embedded pictures]:=False
 $options[wk page index]:=2

 WP EXPORT DOCUMENT(WPArea;"my exported document";wk svg;$options)

Ejemplo 4

Exportación de un documento PDF conforme a PDF/A-2:

 var $options: Object:={}
 $options[wk visible empty images] :=False
 $options[wk pdfa version]:=wk pdfa2 // conformidad "PDF/A-2"
 WP EXPORT DOCUMENT(wpDoc;"invoice.pdf";wk pdf;$options)

Ejemplo 5

Ejemplos de exportación PDF de Factur-X:

  //BASIC (standard profile)
 var $options;$fileInfo : Object
 $options:={}
 $options[wk factur x]:={}
 $options[wk factur x].profile:="BASIC"
 $options[wk factur x].version:="1.0"

 $fileInfo:={}
 $fileInfo.file:=$file  //$file is a 4D.File with an .xml file as target
 $options[wk files]:=[$fileInfo]

 WP EXPORT DOCUMENT(wpDoc;"facturX_basic.pdf";wk pdf;$options)

  //RECHNUNG profile (custom profile)
 $options:={}
 $options[wk factur x]:={}
 $options[wk factur x].profile:="RECHNUNG"
 $options[wk factur x].version:="2.1" //last version for RECHNUNG

 $fileInfo:={}
 $fileInfo.file:=$file  //$file is a 4D.File with an .xml file as target
 $fileInfo.name:="rechnung.xml" //mandatory file name in PDF for RECHNUNG
 $fileInfo.relationship:="Alternative" //mandatory for Germany
 $fileInfo.description:="ZUGFeRD Rechnung"
 $options[wk files]:=[$fileInfo]

 WP EXPORT DOCUMENT(wpDoc;"facturX_rechnung.pdf";wk pdf;$options)

Ejemplo 6

Exportación de un documento docx mediante un objeto File:

var $file : 4D.File

$file:=File("/DATA/test-export")

$options:=New object(wk visible background and anchored elements; False)

WP EXPORT DOCUMENT(WParea; $file; wk docx; $options)

Ver también

4D QPDF (Component) - PDF Get attachments
Exporting to HTML and MIME HTML formats
Importing and Exporting in .docx format
Blog post - 4D Write Pro: Electronic invoice generation
Blog post - 4D Write Pro: Export to PDF with enclosures
WP EXPORT VARIABLE

Descripción​

Parámetro option​

colección wk files​

Objeto wk factur x​

Acerca de los documentos PDF de Factur-X / ZUGFeRD​

Ejemplo 1​

Ejemplo 2​

Ejemplo 3​

Ejemplo 4​

Ejemplo 5​

Ejemplo 6​

Ver también​