SMTP New transporter

SMTP New transporter( server : Object ) : 4D.SMTPTransporter

Parámetros	Tipo		Descripción
server	Object	→	Información del servidor de correo
Resultado	4D.SMTPTransporter	←	Objeto SMTP transporter

Historia

Lanzamiento	Modificaciones
18	Nueva propiedad logFile
17 R5	Nuevas propiedades bodyCharset y headerCharset
17 R4	Añadidos

Descripción

The SMTP New transporter command configures a new SMTP connection according to the server parameter and returns a new SMTP transporter object object. El objeto transportador devuelto se utilizará normalmente para el envío de correos electrónicos.

Este comando no abre ninguna conexión con el servidor SMTP. Este comando no abre ninguna conexión con el servidor SMTP.

La conexión SMTP se cierra automáticamente:

• when the transporter object is destroyed if the keepAlive property is true (default),
• after each .send() function execution if the keepAlive property is set to false.

En el parámetro server, pase un objeto que contenga las siguientes propiedades:

server	Valor por defecto (si se omite)
.acceptUnsecureConnection : Boolean True si se autoriza a 4D establecer una conexión no cifrada	False
.accessTokenOAuth2: Text .accessTokenOAuth2: Object Cadena u objeto token que representa las credenciales de autorización OAuth2. Utilizado sólo con OAUTH2 authationMode. Si se utiliza accessTokenOAuth2 pero se omite authenticationMode, se utiliza el protocolo OAuth 2 (si el servidor lo permite). Not returned in SMTP transporter object.	ninguno
.authenticationMode : Text el modo de autenticación utilizado para abrir la sesión en el servidor de correo	se utiliza el modo de autenticación más seguro soportado por el servidor
.bodyCharset : Text el conjunto de caracteres y la codificación utilizados para la parte del cuerpo del correo electrónico	mail mode UTF8 (US-ASCII_UTF8_QP)
.connectionTimeOut : Integer el tiempo máximo de espera (en segundos) permitido para establecer una conexión con el servidor	30
.headerCharset : Text el conjunto de caracteres y la codificación utilizados para el encabezado del correo electrónico	mail mode UTF8 (US-ASCII_UTF8_QP)
.host : Text el nombre o la dirección IP del servidor local	obligatorio
.keepAlive : Boolean True si la conexión SMTP debe permanecer activa hasta que el objeto transporter sea destruido	True
.logFile : Text la ruta del archivo de registro extendido definido (si existe) para la conexión de correo	ninguno
password : Text contraseña de usuario para la autenticación en el servidor. Not returned in SMTP transporter object.	ninguno
.port : Integer el número de puerto utilizado para las transacciones de correo	587
.sendTimeOut : Integer el tiempo máximo de espera (en segundos) de una llamada a .send( ) antes de que se produzca un timeout	100
.user : Text el nombre de usuario utilizado para la autenticación en el servidor de correo	ninguno

Result

The function returns a SMTP transporter object. Todas las propiedades devueltas son de sólo lectura**.

Ejemplo

 $server:=New object
 $server.host:="smtp.gmail.com" //Obligatorio
 $server.port:=465
 $server.user:="4D@gmail.com"
 $server.password:="XXXX"
 $server.logFile:="LogTest.txt" //Log extendido a guardar en la carpeta Logs
 var $transporter : 4D.SMTPTransporter
 $transporter:=SMTP New transporter($server)

 $email:=New object
 $email.subject:="my first mail "
 $email.from:="4d@gmail.com"
 $email.to:="4d@4d.com;test@4d.com"
 $email.textBody:="Hello World"
 $email.htmlBody:="<h1>Hello World</h1><h4>'Neque porro quisquam est qui dolorem ipsum quia dolor sit amet, consectetur, adipisci velit...'</h4>\
 <p>There are many variations of passages of Lorem Ipsum available."\
 +"The generated Lorem Ipsum is therefore always free from repetition, injected humour, or non-characteristic words etc.</p>"

 $status:=$transporter.send($email)
 If(Not($status.success))
    ALERT("An error occurred sending the mail: "+$status.message)
 End if