WP EXPORT DOCUMENT
WP EXPORT DOCUMENT ( wpDoc ; filePath {; format {; option}} )
WP EXPORT DOCUMENT ( wpDoc ; fileObj {; format {; option}} )
Parámetros | Tipo | Descripción | |
---|---|---|---|
wpDoc | Object | → | Variable 4D Write Pro |
filePath | Text | → | Ruta del archivo exportado |
fileObj | 4D.File | → | Objeto del archivo a exportar |
format | Integer | → | Formato de salida del documento (por ejemplo, .docx, .pdf, etc.) |
option | Object, Integer | → | Opciones de exportación, que pueden variar en función del formato elegido. |
Descripción
El comando WP EXPORT DOCUMENT exporta el objeto wpDoc 4D Write Pro a un documento en disco de acuerdo con el parámetro filePath o fileObj, así como cualquier parámetro opcional.
En wpDoc, pase el objeto 4D Write Pro que desea exportar.
Puede pasar un filePath o fileObj:
-
En filePath, pase la ruta de destino y el nombre del documento a exportar. Si sólo pasa el nombre del documento, se guardará al mismo nivel que el archivo de estructura 4D.
-
En el parámetro fileObj, pase un objeto 4D.File que representa el archivo a exportar.
Puede omitir el parámetro format, en cuyo caso deberá especificar la extensión en filePath. También puede pasar una constante del tema 4D Write Pro Constants en el parámetro format. En este caso, 4D añade la extensión apropiada al nombre del archivo si es necesario. Se soportan los siguientes formatos:
Constante | Valor | Comentario |
---|---|---|
wk 4wp | 4 | El documento 4D Write Pro se guarda en un formato de archivo nativo (HTML comprimido e imágenes guardadas en una carpeta separada). Se incluyen las etiquetas específicas 4D y no se calculan las expresiones 4D. Este formato es especialmente adecuado para guardar y archivar documentos 4D Write Pro en disco sin pérdida alguna. |
wk docx | 7 | Extensión .docx. El documento 4D Write Pro se guarda en formato Microsoft Word. Compatibilidad certificada con Microsoft Word 2010 y versiones posteriores. Las partes del documento exportadas son: Cuerpo / encabezados / pies de página / seccionesPágina / configuración de impresión (márgenes, color de fondo / imagen, bordes, relleno, tamaño de papel / orientación)Imágenes - en línea, ancladas, y patrón de imagen de fondo (definido con wk background image)Variables y expresiones compatibles (número de página, número de páginas, fecha, hora, metadatos). Las variables y expresiones no compatibles serán evaluadas y congeladas antes de export.Links - BookkmarksURLsNote que algunos ajustes de 4D Write Pro pueden no estar disponibles o comportarse de forma diferente en Microsoft Word. |
wk mime html | 1 | El documento 4D Write Pro se guarda como HTML MIME estándar con documentos HTML e imágenes anidadas como partes MIME (codificadas en base64). Se calculan las expresiones y se eliminan las etiquetas específicas de 4D y los enlaces de métodos. Sólo se exportan los cuadros de texto anclados a la vista incrustada (como divs). Este formato es especialmente adecuado para enviar correos electrónicos HTML con el comando. |
wk pdf | 5 | Extensión .pdf. El documento 4D Write Pro se guarda en formato PDF, según el modo vista Página. Los siguientes metadatos se exportan en un documento PDF: Título Autor Asunto Creador del contenido Notas: Las expresiones se congelan automáticamente al exportar el documento Los enlaces a métodos NO se exportan |
wk svg | 8 | La página del documento 4D Write Pro se guarda en formato SVG, según el modo vista Página. Nota: al exportar a SVG, sólo puede exportar una página cada vez. Utilice el wk page index para especificar qué página exportar. |
wk web page complete | 2 | Extensión .htm o .html. El documento se guarda como HTML estándar y sus recursos se guardan por separado. Se eliminan las etiquetas 4D y los enlaces a métodos 4D y se calculan las expresiones. Sólo se exportan los cuadros de texto anclados a la vista incrustada (como divs). Only text boxes anchored to embedded view are exported (as divs). |
Notas:
- "Etiquetas específicas 4D" significa XHTML 4D con un espacio de nombres 4D y estilos CSS 4D.
- Para más información sobre el formato de documento 4D Write Pro, consulte el formato del documento .4wp.
- Para ver una lista de las diferencias o incompatibilidades conocidas al utilizar el formato .docx, consulte Importación y exportación en formato .docx.
- Para obtener más información sobre la exportación a formato SVG, consulte Exportar a formato SVG.
Parámetro option
Pase un objeto en option conteniendo los valores para definir las propiedades del documento exportado. Las siguientes propiedades están disponibles:
Constante | Valor | Comentario |
---|---|---|
wk CID host domain name | cidHostDomain | Nombre de dominio de host CID: dominio de host que se añadirá a las URL CID generadas incluyendo una "@" como separador. Disponible sólo cuando se utiliza el formato wk mime html . |
wk embedded pictures | embeddedPictures | Sólo para exportación SVG. Establece si las imágenes se incrustan en el archivo .svg exportado cuando se llama a WP EXPORT DOCUMENT. Valores disponibles: |
wk factur x | facturX | Sólo para exportación en PDF. Valor: objeto que configura una exportación PDF "Factur-X (ZUGFeRD)" (ver wk factur x object). |
wk files | Histórico | Sólo para exportación en PDF. Valor: colección de objetos, cada uno de los cuales describe un archivo que se integrará en el documento final (ver wk files collection). Esta funcionalidad sólo se admite en documentos PDF/A-3: cuando se utiliza el atributo wk files , se establece automáticamente la versión "PDF/A-3" (se ignora el atributo wk pdfa version ). En caso de una exportación de Factur-X PDF (ver abajo), el primer objeto de la colección debe contener el archivo Factur-X xml. |
wk google fonts tag | googleFontsTag | Sólo para exportación SVG. Define la regla de importación para fuentes google en el SVG exportado. Valores posibles: |
wk HTML pretty print | htmlPrettyPrint | El código HTML está formateado para facilitar su lectura. |
wk max picture DPI | maxPictureDPI | Se utiliza para reducir imágenes a la resolución preferida. Para imágenes SVG en Windows, utilizado para la rasterización. Valores por defecto: 300 (for wk optimized for = wk print) 192 (for wk optimized for = wk screen) Valor máximo posible: 1440 |
wk optimized for | optimizedFor | Define cómo se optimiza un documento exportado en función de su soporte. Valores posibles:wk print (valor por defecto para wk pdf y wk svg ) Las imágenes de mapa de bits pueden reducirse utilizando los PPP definidos por wk max picture DPI o 300 (valor por defecto) y pueden convertirse a PNG si el códec no es compatible con el tipo de exportación. Las imágenes vectoriales se convierten a PNG utilizando los PPP definidos por wk max picture DPI o 300 (sólo Windows). Si una imagen contiene más de un formato, se utiliza el mejor formato para la impresión (por ejemplo, .tiff en lugar de .jpg)wk screen (valor por defecto para wk web page complete y wk mime html ). Las imágenes de mapa de bits pueden reducirse utilizando los PPP definidos por wk max picture DPI o 192 (valor por defecto) y pueden convertirse a JPEG (imágenes opacas) o PNG (imágenes transparentes) si el códec no es compatible con el tipo de exportación. Las imágenes vectoriales se convierten a PNG utilizando los PPP definidos por wk max picture DPI o 192 (sólo Windows). Si una imagen contiene más de un formato, se utiliza el formato para la representación en pantalla.wk docx siempre se optimizan para la impresión wk (se ignora la opción wk optimized for). |
wk page index | pageIndex | Sólo para exportación SVG. Índice de la página a exportar a formato svg (por defecto es 1). El índice de páginas comienza en 1 para la primera página del documento. Nota: el índice de páginas es independiente de la numeración de páginas. |
wk pdfa version | pdfaVersion | Exporta PDF conforme a una versión PDF/A. Para más información sobre las propiedades y versiones de PDF/A, consulte la página PDF/A en Wikipedia. Valores posibles: wk pdfa2 : exporta a la versión "PDF/A-2"wk pdfa3 : exporta a la versión "PDF/A-3"wk pdfa2 puede exportar a PDF/A-2 o PDF/A-3 o superior, dependiendo de la implementación de la plataforma. Además, wk pdfa3 significa "exporta a al menos PDF/A-3". En Windows, el archivo PDF de salida siempre será igual a la conformidad deseada. |
wk recompute formulas | recomputeFormulas | Define si las fórmulas deben volver a calcularse cuando se exportan. Valores posibles: |
wk visible background and anchored elements | visibleBackground | Muestra o exporta imágenes/color de fondo, imágenes ancladas y cuadros de texto (para mostrar, efecto visible sólo en modo de vista Página o Anidado). Valores posibles: True/False |
wk visible empty images | visibleEmptyImages | Muestra o exporta un rectángulo negro por defecto para las imágenes que no se pueden cargar o calcular (imágenes vacías o imágenes en un formato no compatible). Valores posibles: True/False. Valor por defecto: True Si el valor es False, los elementos de imagen que falten no se mostrarán en absoluto aunque tengan bordes, ancho, alto o fondo; esto puede afectar al diseño de la página para imágenes en línea. |
wk visible footers | visibleFooters | Muestra o exporta los pies de página (para la visualización, efecto visible sólo en el modo vista Página). Valores posibles: True/False |
wk visible headers | visibleHeaders | Muestra o exporta los encabezados (para la visualización, efecto visible sólo en el modo vista Página). Valores posibles: True/False |
wk visible references | visibleReferences | Muestra o exporta todas las expresiones 4D insertadas en el documento como referencias. Valores posibles: True/False |
wk whitespace | whitespace | Define el valor css "white-space" para los formatos de exportación wk mime html y wk web page complete . El estilo white-space css se aplica a los párrafos. Valores posibles: "normal", "nowrap", "pre", "pre-wrap" (por defecto), "pre-line", "break-spaces". |
The following table indicates the option available per export format:
wk 4wp | wk docx | wk mime html | wk pdf | wk web page complete | wk svg | |
---|---|---|---|---|---|---|
wk CID host domain name | - | - | - | - | - | |
wk embedded pictures | - | - | - | - | - | |
wk factur x | - | - | - | - | - | |
wk files | - | - | - | - | - | |
wk google fonts tag | - | - | - | - | - | |
wk HTML pretty print | - | |||||
wk max picture DPI | - | siempre 300 | - | |||
wk optimized for | - | always wk print | always wk print | - | ||
wk page index | - | - | - | - | - | |
wk pdfa version | - | - | - | - | - | |
wk recompute formulas | - | - | ||||
wk visible background and anchored elements | - | siempre true | - | |||
wk visible empty images | - | - | ||||
wk visible footers | - | siempre true | siempre false | - | ||
wk visible headers | - | siempre true | siempre false | - | ||
wk visible references | - | - | - | - | ||
wk whitespace | - | - | - | - |
Nota de compatibilidad: pasar un valor largo en longint es compatible por razones de compatibilidad, pero se recomienda usar un parámetro objeto.
colección wk files
La propiedad wk files permite exportar un PDF con archivos adjuntos. Esta propiedad debe contener una colección de objetos que describan los archivos que se integrarán en el documento final. Cada objeto de la colección puede contener las siguientes propiedades:
Propiedad | Tipo | Description |
---|---|---|
name | Text | Nombre de archivo. Opcional si se utiliza la propiedad file, en cuyo caso el nombre se infiere por defecto a partir del nombre del archivo. Obligatorio si se utiliza la propiedad data (excepto para el primer archivo de una exportación Factur-X, en cuyo caso el nombre del archivo es automáticamente "factur-x.xml", ver abajo) |
description | Text | Opcional. Si se omite, el valor por defecto para el primer archivo de exportación a Factur-X es "Factur-X/ZUGFeRD Invoice", en caso contrario vacío. |
mimeType | Text | Opcional. Si se omite, el valor predeterminado puede adivinarse normalmente a partir de la extensión del archivo; de lo contrario, se utiliza "application/octet-stream". Si se pasa, asegúrese de utilizar un tipo mime ISO, de lo contrario el archivo exportado podría no ser válido. |
data | Texto o BLOB | Obligatorio si falta la propiedad file |
file | Objeto 4D.File | Obligatorio si falta la propiedad data, ignorado en caso contrario. |
relationship | Text | Opcional. Si se omite, el valor por defecto es "Data". Valores posibles para el primer archivo Factur-X:para los perfiles BASIC, EN 16931 o EXTENDED: "Alternative", "Source" o "Data" ("Alternative" sólo para factura alemana)para perfiles MINIMUM y BASIC WL: Sólo "Data": "Alternative", "Source" o "Data" (con restricciones quizás dependiendo del país: ver la especificación del perfil para más información sobre otros perfiles - por ejemplo para el perfil RECHNUNG sólo se permite "Alternative") para otros archivos (excepto archivo Factur-X invoice): "Alternative", "Source", "Data", "Supplement" o "Unspecified" cualquier otro valor genera un error. |
Si el parámetro option también contiene una propiedad wk factur x, entonces el primer elemento de la colección wk files debe ser el fichero xml de la factura Factur-X (ZUGFeRD) (ver más abajo).
Los archivos PDF adjuntos solo son compatibles con la versión PDF/A-3. Cuando pasas la propiedad wk files, la versión "PDF/A-3" se utiliza automáticamente.
Objeto wk factur x
La propiedad wk factur x es un objeto que puede contener hasta dos propiedades:
Propiedad | Tipo | Description |
---|---|---|
profile | Text | Opcional. Si se omite, profile se determina a partir del archivo xml o texto suministrado (que debe utilizar un perfil estándar). Si se pasa, puede ser un nombre de perfil no estándar (para utilizar otros perfiles, por ejemplo RECHNUNG). Nota: los nombres estándar de los perfiles son: MINIMUM, BASIC WL, BASIC, EN 16931 (también conocido como COMFORT, que es un alias), EXTENDED. |
version | Text | Opcional. El valor por defecto es "1.0" |
Acerca de los documentos PDF de Factur-X / ZUGFeRD
Factur-X / ZUGFeRD es una norma europea para las facturas electrónicas híbridas (PDF para usuarios y datos XML para la automatización de procesos). Para más información, lea esta entrada del blog.
Para activar una exportación PDF "Factur-X", pase las propiedades wk factur x y wk files en el parámetro option (ver el ejemplo 5). En este caso:
- se genera un Factur-X (ZUGFeRD) PDF,
- el primer elemento de la colección wk files se utiliza como archivo xml Factur-X,
- si la propiedad wk files falta o contiene una colección vacía, o si su primer elemento no es un archivo xml, se genera un error.
Para ver un ejemplo detallado de la implementación de la exportación Factur-X / ZUGFeRD, puede descargar este proyecto HDI 4D.
Ejemplo 1
Quiere exportar el contenido del objeto 4D Write Pro myArea a los formatos HTML y PDF:
// exportar HTML
var $option : Object
$option:=New object
$option[wk recompute formulas]:=False
$option[wk HTML pretty print]:=False
$option[wk optimized for]:=wk print
$option[wk max picture DPI]:=600 //reemplazar el valor por defecto para imprimir (300 DPI)
WP EXPORT DOCUMENT(myArea;$path;wk web page complete;$option)
//export PDF
var $option : Object
$option:=New object
$option[wk visible headers]:=True
$option[wk visible footers]:=True
$option[wk visible background]:=True
$option[wk max picture DPI]:=96 //reemplazar el valor por defecto para la pantalla (192 DPI) para limitar el tamaño del documento
$option[wk optimized for]:=wk screen
$option[wk recompute formulas]:=True
WP EXPORT DOCUMENT(myArea;$path;wk pdf;$option)
Ejemplo 2
Quiere exportar el contenido del objeto 4D Write Pro myArea al formato .4wp:
var $path : Text
Case of
:(Form event code=On Clicked)
$path:=Get 4D folder(Database folder)+"Export"+Folder separator
$path:=Select document($path;".4wp";" title";File name entry)
If($path#"")
WP EXPORT DOCUMENT(myArea;document;wk 4wp)
End if
End case
Ejemplo 3
Para exportar la segunda página del documento como SVG y exportar las imágenes desde el documento:
var $options : Object
$options:=New object
$options[wk embedded pictures]:=False
$options[wk page index]:=2
WP EXPORT DOCUMENT(WPArea;"my exported document";wk svg;$options)
Ejemplo 4
Exportación de un documento PDF conforme a PDF/A-2:
var $options: Object:={}
$options[wk visible empty images] :=False
$options[wk pdfa version]:=wk pdfa2 // conformidad "PDF/A-2"
WP EXPORT DOCUMENT(wpDoc;"invoice.pdf";wk pdf;$options)
Ejemplo 5
Ejemplos de exportación PDF de Factur-X:
//BASIC (perfil estándar)
var $options;$fileInfo : Object
$options:={}
$options[wk factur x]:={}
$options[wk factur x].profile:="BASIC"
$options[wk factur x].version:="1.0"
$fileInfo:={}
$fileInfo.file:=$file //$file is a 4D.File with an .xml file as target
$options[wk files]:=[$fileInfo]
WP EXPORT DOCUMENT(wpDoc;"facturX_basic.pdf";wk pdf;$options)
//Perfil RECHNUNG (perfil personalizado)
$options:={}
$options[wk factur x]:={}
$options[wk factur x].profile:="RECHNUNG"
$options[wk factur x].version:="2.1" //última versión para RECHNUNG
$fileInfo:={}
$fileInfo.file:=$file //$file es un 4D.File con un archivo .xml como objetivo
$fileInfo.name:="rechnung.xml" //nombre de archivo obligatorio en PDF para RECHNUNG
$fileInfo.relationship:="Alternative" //obligatorio para Alemania
$fileInfo.description:="ZUGFeRD Rechnung"
$options[wk files]:=[$fileInfo]
WP EXPORT DOCUMENT(wpDoc;"facturX_rechnung.pdf";wk pdf;$options)
Ejemplo 6
Exportación de un documento docx mediante un objeto File:
var $file : 4D.File
$file:=File("/DATA/test-export")
$options:=New object(wk visible background and anchored elements; False)
WP EXPORT DOCUMENT(WParea; $file; wk docx; $options)
Ver también
4D QPDF (Component) - PDF Get attachments
Exporting to HTML and MIME HTML formats
Importing and Exporting in .docx format
Blog post - 4D Write Pro: Electronic invoice generation
Blog post - 4D Write Pro: Export to PDF with enclosures
WP EXPORT VARIABLE