WP Table get cells
WP Table get cells ( objCible ) | ( refTableau ; debutCol ; debutLigne {; nbCols{; nbLignes}} ) -> Résultat
| Paramètre | Type | Description | |
|---|---|---|---|
| objCible | Objet | 🡒 | Plage ou élément ou document 4D Write Pro |
| refTableau | Objet | 🡒 | Référence de tableau |
| debutCol | Entier long | 🡒 | Position de la colonne de la première cellule |
| debutLigne | Entier long | 🡒 | Position de la ligne de la première cellule |
| nbCols | Entier long | 🡒 | Nombre de colonnes à lire |
| nbLignes | Entier long | 🡒 | Nombre de lignes à lire |
| Résultat | Objet | 🡐 | Nouvelle plage contenant les cellules |
Description
La commande WP Table get cells retourne un nouvel objet cellule contenant la sélection de cellules de objCible ou de refTableau (définies par debutCol, debutLigne, nbCols et nbLignes).
Passez soit :
- objCible :
- une plage, ou
- un élément (ligne / paragraphe / corps / en-tête / pied / image en ligne / section / sous-section), ou
- un document 4D Write Pro
Si objCible n'intersecte pas une plage de tableau ou de texte là où une sélection de cellules peut être récupérée, la commande retourne Null.
OU
- debutCol et debutLigne - déterminent les coordonnées en haut à gauche de la première cellule à lire.
- (optionnel) nbCols et nbLignes - indiquent respectivement le nombre de colonnes et de lignes à lire pour la plage de cellules.
Si nbLignes est omis, une seule ligne est retounée. Si nbCols et nbLignes sont omis, la plage retournée contient une seule cellule.
Si debutCol plus nbCols ou debutLigne plus nbLignes excède le nombre de colonnes/lignes dans refTableau, ou si debutCol ou debutLigne est plus grand que le nombre de colonnes/lignes dans refTableau, la plage retournée contient le maximum de colonnes/lignes.
Exemple 1
Vous voulez modifier les attributs d'une plage de cellules :
var $wpTable;$wpRange;$wpRow1;$wpRow2;$wpRow3;$wpRow4;$wpRow5;$cells : Object
$wpRange:=WP Create range(WParea;wk start text;wk end text)
$wpTable:=WP Insert table($wpRange;wk append)
$wpRow1:=WP Table append row($wpTable;"Paul";"Smith";25)
$wpRow2:=WP Table append row($wpTable;"John";"Richmond";40)
$wpRow3:=WP Table append row($wpTable;"Mary";"Trenton";18)
$wpRow4:=WP Table append row(($wpTable;"Christopher";"Lee";53)
$wpRow5:=WP Table append row(($wpTable;"Henry";"Cartier";42)
$cells:=WP Table get cells($wpTable;2;2;2;2)
WP SET ATTRIBUTES($cells;wk background color;0x00E0E0E0)
WP SET ATTRIBUTES($cells;wk text color;"blue")
WP SET ATTRIBUTES($cells;wk border color;0x00E000E0)
WP SET ATTRIBUTES($cells;wk text align;wk center)
Résultat :
Exemple 2
Obtenir une plage de cellules à partir de la cellule "5x7" et jusqu'à la fin de la ligne :
$cellRange:=WP Table get cells(tableRef;5;7;MAXLONG;1)
Obtenir une plage de cellules à partir de la cellule "5x7" et jusqu'à la fin de la colonne :
$cellRange:=WP Table get cells(tableRef;5;7;1;MAXLONG)
Obtenir une plage de cellules à partir de la cellule "5x7" et jusqu'à la fin du tableau :
$cellRange:=WP Table get cells(tableRef;5;7;MAXLONG;MAXLONG)
Exemple 3
Vous souhaitez récupérer les cellules sélectionnées par un utilisateur :
var $userSelection;$cells : Object
$userSelection:=WP Selection range(myWPArea)
$cells:=WP Table get cells($userSelection)