METHOD GET MODIFICATION DATE

METHOD GET MODIFICATION DATE ( chemin ; dateMod ; heureMod {; *} )

Paramètre	Type		Description
chemin	Text, Text array	→	Texte ou Tableau texte contenant un ou plusieurs chemin(s) de méthode(s)
dateMod	Date, Date array	←	Date(s) de modification de méthode(s)
heureMod	Time, Integer array	←	Heure(s) de modification de méthode(s)
*	Opérateur	→	Si passé = la commande s’applique à la base hôte lorsqu’elle est exécutée depuis un composant (paramètre ignoré hors de ce contexte)

Cette commande n'est pas thread-safe, elle ne peut pas être utilisée dans du code préemptif.

Description

La commande METHOD GET MODIFICATION DATE retourne dans les paramètres dateMod et heureMod les dates et heures de dernière modification de la ou des méthode(s) désignée(s) par le paramètre chemin.

Vous pouvez utiliser deux types de syntaxes, basées soit sur des tableaux, soit sur des variables :

 var vTchemin : Text // variables
 var vDate : Date
 var vHeure : Time
 METHOD GET MODIFICATION DATE(vTchemin;vDate;vHeure) // date et heure d’une seule méthode

 ARRAY TEXT(tabChemins;0) // tableaux
 ARRAY DATE(tabDates;0)
 ARRAY LONGINT(tabHeures;0)
 METHOD GET MODIFICATION DATE(tabChemins;tabDates;tabHeures) // dates et heures de plusieurs méthodes

Il n’est pas possible de mixer les deux syntaxes.

Si la commande est exécutée depuis un composant, elle s’applique par défaut aux méthodes du composant. Si vous passez le paramètre *, elle accède aux méthodes de la base hôte.

Exemple 1

Vous souhaitez connaître les dates et heures de modification de plusieurs méthodes :

 ARRAY TEXT(tabChemins;0)
 APPEND TO ARRAY(tabChemins;"MaMethode1")
 APPEND TO ARRAY(tabChemins;"MaMethode2")
 ...
 ARRAY DATE(tabDates;0)
 ARRAY LONGINT(tabHeures;0)
 METHOD GET MODIFICATION DATE(tabChemins;tabDates;tabHeures)

Exemple 2

Vous souhaitez obtenir les dates de modification des méthodes d'un module, préfixées "Web_". Il n’est pas possible d’utiliser "@" dans le chemin, vous pouvez cependant écrire :

 ARRAY TEXT($_webMethod;0)      
 METHOD GET NAMES($_webMethod;"Web_@")
 ARRAY DATE($_date;0)
 ARRAY LONGINT($_time;0)
 METHOD GET MODIFICATION DATE($_webMethod;$_date;$_time)