バージョン: 開発中

MAIL Convert from MIME

履歴

リリース	内容
18	追加

MAIL Convert from MIME( mime : Blob ) : Object
MAIL Convert from MIME( mime : Text ) : Object

引数	型		説明
mime	Blob, Text	→	MIME形式のメール
戻り値	Object	←	Email オブジェクト

説明

MAIL Convert from MIME コマンドは、MIMEドキュメントを有効な Emailオブジェクトへと変換します。

戻り値の Email オブジェクトのフォーマットは JMAP specification に準拠します。

mime には、変換する有効な MIME ドキュメントを渡します。これはどのメールサーバーまたはアプリケーションから提供されたものでも可能です。 mime 引数として、BLOB またはテキストを渡すことができます。 MIME がファイルから渡された場合、文字セットと改行コード変換に関する問題を避けるため、BLOB型の引数を使用することが推奨されます。

返されるオブジェクト

Email オブジェクト。

例題 1

テキストドキュメントとして保存された MIME のメールのテンプレートを読み込み、メールを送信します。

var $mime: Blob
var $mail;$server;$transporter;$status: Object

$mime:=File("/PACKAGE/Mails/templateMail.txt").getContent())

$mail:=MAIL Convert from MIME($mime)
$mail.to:="smith@mail.com"
$mail.subject:="Hello world"

$server:=New object
$server.host:="smtp.gmail.com"
$server.port:=465
$server.user:="test@gmail.com"
$server.password:="XXXX"

$transporter:=SMTP New transporter($server)
$status:=$transporter.send($mail)

例題 2

この例題では、ピクチャーが含まれた 4D Write Pro ドキュメントを直接送信します:

var $mime: Blob
var $email;$server;$transporter;$status: Object

// 4D Write Pro ドキュメントを MIME に書き出します
WP EXPORT VARIABLE(WParea;$mime;wk mime html)

// 4D Write Pro MIME 変数をメールオブジェクトに変換します
$email:=MAIL Convert from MIME($mime)

// Email オブジェクトのヘッダーを設定します
$email.subject:="4D Write Pro HTML body"
$email.from:="YourEmail@gmail.com"
$email.to:="RecipientEmail@mail.com"

$server:=New object
$server.host:="smtp.gmail.com"
$server.port:=465
$server.user:="YourEmail@gmail.com"
$server.password:="XXXX"

$transporter:=SMTP New transporter($server)
$status:=$transporter.send($email)

説明​

返されるオブジェクト​

例題 1​

例題 2​

説明

返されるオブジェクト

例題 1

例題 2