TCPListener

The TCPListener class allows you to create and configure a TCP server in 4D. Once the TCP listener is instantiated, you can receive client TCP connections and communicate using any protocol supporting TCP.

The TCPListener class is available from the 4D class store. You can create a TCP server using the 4D.TCPListener.new() function, which returns a TCPListener object.

All TCPListener class functions are thread-safe.

História

Release	Mudanças
20 R9	Classe adicionada

Exemplo

property listener : 4D.TCPListener

Class constructor($port : Integer)
	
	This.listener:=4D.TCPListener.new($port; This)
		
Function terminate()
	
	This.listener.terminate()
	
Function onConnection($listener : 4D.TCPListener; $event : 4D.TCPEvent)->$result
    	//when connected, start a server to handle the communication
	If($event.address # "192.168.@") 
		$result:=Null //in some cases you can reject the connection
	Else
		$result:=cs.MyAsyncTCPConnection.new(This) //see TCPConnection class
	End if
	
Function onError($listener : 4D.TCPListener; $event : 4D.TCPEvent)
	
Function onTerminate($listener : 4D.TCPListener; $event : 4D.TCPEvent)

nota

See example in TCPConnection class for a description of the MyAsyncTCPConnection user class.

TCPListener Object

A TCPListener object is a shared object.

TCPListener objects provide the following properties and functions:

errors : Collection a collection of error objects associated with the connection
port : Number the port number of the machine
.terminate() closes the listener and releases the port

4D.TCPListener.new()

4D.TCPListener.new( port : Number ; options : Object ) : 4D.TCPListener

Parâmetro	Tipo		Descrição
port	Number	->	TCP port to listen
options	Object	->	Configuration options for the listener
Resultados	4D.TCPListener	<-	New TCPListener object

Descrição

The 4D.TCPListener.new() function creates a new TCP server listening to the specified port using the defined options, and returns a 4D.TCPListener object.

options parameter

In the options parameter, pass an object to configure the listener and all the TCPConnections it creates:

Propriedade	Tipo	Descrição	Por padrão
onConnection	Formula	Callback when a new connection is established. The Formula receives two parameters ($listener and $event, see below) and must return either null/undefined to prevent the connection or an option object that will be used to create the TCPConnection.	Indefinido
onError	Formula	Callback triggered in case of an error. The Formula receives the TCPListener object in $listener	Indefinido
onTerminate	Formula	Callback triggered just before the TCPListener is closed. The Formula receives the TCPListener object in $listener	Indefinido

Funções Callback

Callback functions receive up to two parameters:

Parâmetro	Tipo	Descrição
$listener	TCPListener object	The current TCP listener instance.
$event	objeto TCPEvent	Contains information about the event.

Sequence of Callback Calls:

1. onConnection is triggered each time a connection is established.
2. onError is triggered if an error occurs.
3. onTerminate is always triggered just before a connection is terminated.

TCPEvent object

Um objeto TCPEvent é retornado quando uma função de callback é chamada.

.errors

errors : Collection

Descrição

The .errors property contains a collection of error objects associated with the connection. Each error object includes the error code, a description, and the signature of the component that caused the error.

Propriedade		Tipo	Descrição
errors		Collection	pilha de erros 4D em caso de erro
	[].errCode	Number	Código de erro 4D
	[].message	Text	Descrição do erro 4D
	[].componentSignature	Text	Assinatura da componente interna que devolveu o erro

.port

port : Number

Descrição

The .port property contains the port number of the machine. Essa propriedade é somente leitura.

.terminate()

.terminate()

Parâmetro	Tipo		Descrição
			Não exige nenhum parâmetro

Descrição

The terminate() function closes the listener and releases the port.